CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 4)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 # This setting of SOVERSION assumes that any API change
  38 # will increment either the minor or major version number of openjpeg
  39 SET(OPENJPEG_LIBRARY_PROPERTIES
  40   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  41   SOVERSION "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}"
  42 )
  43 # You will also need to define a value for the following variables:
  44 # OPENJPEG_INSTALL_BIN_DIR          - binary dir (executables)
  45 # OPENJPEG_INSTALL_LIB_DIR          - library dir (libs)
  46 # OPENJPEG_INSTALL_DATA_DIR         - share dir (say, examples, data, etc)
  47 # OPENJPEG_INSTALL_INCLUDE_DIR      - include dir (headers)
  48
  49
  50 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  51 # warnings
  52 IF(WIN32)
  53   IF(NOT BORLAND)
  54     IF(NOT CYGWIN)
  55       IF(NOT MINGW)
  56         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  57           ADD_DEFINITIONS(
  58             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  59             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  60             -D_CRT_MANAGED_FP_NO_DEPRECATE
  61             -D_CRT_NONSTDC_NO_DEPRECATE
  62             -D_CRT_SECURE_NO_DEPRECATE
  63             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  64             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  65             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  66             -D_CRT_VCCLRIT_NO_DEPRECATE
  67             -D_SCL_SECURE_NO_DEPRECATE
  68             )
  69         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  70       ENDIF(NOT MINGW)
  71     ENDIF(NOT CYGWIN)
  72   ENDIF(NOT BORLAND)
  73 ENDIF(WIN32)
  74
  75
  76 # --------------------------------------------------------------------------
  77 # Install directories
  78
  79 STRING(TOLOWER ${PROJECT_NAME} projectname)
  80 SET(subdir "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  81
  82 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  83   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  84 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  85
  86 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  87   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  88 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  89
  90 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  91   SET(OPENJPEG_INSTALL_DATA_DIR "share/${subdir}")
  92 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  93
  94 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  95   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  96 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  97
  98 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
  99   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
 100 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
 101
 102 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 103   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${subdir}")
 104 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 105
 106 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 107   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${subdir}
 108     CACHE INTERNAL "")
 109 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 110
 111 #-----------------------------------------------------------------------------
 112 # Test for some required system information.
 113 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityC.cmake)
 114
 115 #-----------------------------------------------------------------------------
 116 # Test for getopt being available in this system
 117 INCLUDE (${PROJECT_SOURCE_DIR}/CMake/CheckHaveGetopt.cmake )
 118
 119 #-----------------------------------------------------------------------------
 120 # Setup file for setting custom ctest vars
 121 CONFIGURE_FILE(
 122   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 123   ${CMAKE_CURRENT_BINARY_DIR}/CTestCustom.cmake
 124   @ONLY
 125   )
 126
 127 #-----------------------------------------------------------------------------
 128 # OpenJPEG build configuration options.
 129 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 130
 131 #-----------------------------------------------------------------------------
 132 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 133 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 134 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 135
 136
 137 # configure name mangling to allow multiple libraries to coexist
 138 # peacefully
 139 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 140 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 141 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 142                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 143                @ONLY IMMEDIATE)
 144 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 145
 146 #-----------------------------------------------------------------------------
 147 # pkgconfig support
 148 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc )
 149 INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 150 INSTALL( CODE
 151   "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink \"libopenjpeg1.pc\" \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 152
 153 #-----------------------------------------------------------------------------
 154 # Always build the library
 155 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 156 SUBDIRS(libopenjpeg)
 157
 158 #-----------------------------------------------------------------------------
 159 # Build CODEC executables ?
 160 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 161 IF(BUILD_CODEC)
 162   SUBDIRS(codec)
 163 ENDIF(BUILD_CODEC)
 164
 165 #-----------------------------------------------------------------------------
 166 # Build MJ2 executables ?
 167 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 168 IF(BUILD_MJ2)
 169   SUBDIRS(mj2)
 170 ENDIF(BUILD_MJ2)
 171
 172 #-----------------------------------------------------------------------------
 173 # Build JPWL executables ?
 174 OPTION(BUILD_JPWL "Build the JPWL executables" OFF)
 175 IF(BUILD_JPWL)
 176   SUBDIRS(jpwl)
 177 ENDIF(BUILD_JPWL)
 178
 179 #-----------------------------------------------------------------------------
 180 # Build JP3D executables ?
 181 OPTION(BUILD_JP3D "Build the JP3D executables" OFF)
 182 IF(BUILD_JP3D)
 183   SUBDIRS(jp3d)
 184 ENDIF(BUILD_JP3D)
 185
 186 #-----------------------------------------------------------------------------
 187 # Build INDEXER_JPIP executables ?
 188 OPTION(BUILD_INDEXER_JPIP "Build the INDEXER_JPIP executables" OFF)
 189 IF(BUILD_INDEXER_JPIP AND NOT UNIX)
 190   SUBDIRS(indexer_JPIP)
 191 ENDIF(BUILD_INDEXER_JPIP AND NOT UNIX)
 192
 193 #-----------------------------------------------------------------------------
 194 # Build DOCUMENTATION ?
 195 OPTION(BUILD_DOC "Build the doxygen documentation" OFF)
 196 IF(BUILD_DOC)
 197   SUBDIRS(doc)
 198 ENDIF(BUILD_DOC)
 199
 200 #-----------------------------------------------------------------------------
 201 # For openjpeg team if they ever want CDash+CMake
 202 OPTION(BUILD_TESTING "Build the tests." OFF)
 203 IF(BUILD_TESTING)
 204   ENABLE_TESTING()
 205   INCLUDE(CTest)
 206 ENDIF(BUILD_TESTING)
 207
 208 # Adding test with dataset from:
 209 # http://www.crc.ricoh.com/~gormish/jpeg2000conformance/
 210 # -> wget http://www.crc.ricoh.com/~gormish/jpeg2000conformance/j2kp4files_v1_5.zip
 211 # http://www.jpeg.org/jpeg2000guide/testimages/testimages.html
 212 #-----------------------------------------------------------------------------
 213 # Adding JPEG2000_CONFORMANCE_DATA_ROOT
 214 FIND_PATH(JPEG2000_CONFORMANCE_DATA_ROOT testimages.html
 215   ${OPENJPEG_SOURCE_DIR}/../jpeg2000testimages
 216   $ENV{JPEG2000_CONFORMANCE_DATA_ROOT}
 217 )
 218
 219 #-----------------------------------------------------------------------------
 220 # Compiler specific flags:
 221 IF(CMAKE_COMPILER_IS_GNUCC)
 222   # For all builds, make sure openjpeg is std99 compliant:
 223   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 224   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 225   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 226 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 227
 228 # install all targets referenced as OPENJPEGTargets
 229 install(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 230 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 231   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 232   @ONLY
 233 )
 234 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 235   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 236 )
 237 # install CHANGES and LICENSE
 238 INSTALL(
 239   FILES       CHANGES
 240               LICENSE
 241   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 242 #
 243 IF(UNIX OR CYGWIN)
 244   SET(CMAKE_INCLUDE_PATH /usr/include /usr/local/include /opt/include
 245         /opt/local/include /usr/include/libpng /usr/include/libpng14
 246         /usr/include/libpng12 /usr/local/include/libpng
 247         /usr/local/include/libpng14 /usr/local/include/libpng12
 248         /opt/include/libpng /opt/include/libpng14 /opt/include/libpng12
 249         /opt/local/include/libpng /opt/local/include/libpng14
 250         /opt/local/include/libpng12 )
 251   SET(CMAKE_LIBRARY_PATH /usr/lib /usr/local/lib /opt/lib /opt/local/lib)
 252 ELSEIF(WIN32)
 253   SET(CMAKE_INCLUDE_PATH ${OPENJPEG_SOURCE_DIR}/libs/libtiff
 254         ${OPENJPEG_SOURCE_DIR}/libs/png ${OPENJPEG_SOURCE_DIR}/libs/lcms2
 255         C:/WINDOWS/system32/user )
 256   SET(CMAKE_LIBRARY_PATH ${OPENJPEG_SOURCE_DIR}/libs/libtiff
 257         ${OPENJPEG_SOURCE_DIR}/libs/png ${OPENJPEG_SOURCE_DIR}/libs/lcms2
 258         C:/WINDOWS/system32/user )
 259 ENDIF()
 260 #
 261 FIND_FILE(HAVE_STRINGS_H_FOUND strings.h)
 262 IF(NOT HAVE_STRINGS_H_FOUND STREQUAL "HAVE_STRINGS_H_FOUND-NOTFOUND")
 263   FIND_FILE(HAVE_STRINGS_H strings.h)
 264   SET(HAS_STRINGS_H 1)
 265 ENDIF()
 266 FIND_FILE(HAVE_INTTYPES_H_FOUND inttypes.h)
 267 IF(NOT HAVE_INTTYPES_H_FOUND STREQUAL "HAVE_INTTYPES_H_FOUND-NOTFOUND")
 268   FIND_FILE(HAVE_INTTYPES_H inttypes.h)
 269   SET(HAS_INTTYPES_H 1)
 270 ENDIF()
 271 FIND_FILE(HAVE_MEMORY_H_FOUND memory.h)
 272 IF(NOT HAVE_MEMORY_H_FOUND STREQUAL "HAVE_MEMORY_H_FOUND-NOTFOUND")
 273   FIND_FILE(HAVE_MEMORY_H memory.h)
 274   SET(HAS_MEMORY_H 1)
 275 ENDIF()
 276 FIND_FILE(HAVE_STDINT_H_FOUND stdint.h)
 277 IF(NOT HAVE_STDINT_H_FOUND STREQUAL "HAVE_STDINT_H_FOUND-NOTFOUND")
 278   FIND_FILE(HAVE_STDINT_H stdint.h)
 279   SET(HAS_STDINT_H 1)
 280 ENDIF()
 281 FIND_FILE(HAVE_STDLIB_H_FOUND stdlib.h)
 282 IF(NOT HAVE_STDLIB_H_FOUND STREQUAL "HAVE_STDLIB_H_FOUND-NOTFOUND")
 283   FIND_FILE(HAVE_STDLIB_H stdlib.h)
 284   SET(HAS_STDLIB_H 1)
 285 ENDIF()
 286 FIND_FILE(HAVE_STRING_H_FOUND string.h)
 287 IF(NOT HAVE_STRING_H_FOUND STREQUAL "HAVE_STRING_H_FOUND-NOTFOUND")
 288   FIND_FILE(HAVE_STRING_H string.h)
 289   SET(HAS_STRING_H 1)
 290 ENDIF()
 291 FIND_FILE(HAVE_SYS_STAT_H_FOUND sys/stat.h)
 292 IF(NOT HAVE_SYS_STAT_H_FOUND STREQUAL "HAVE_SYS_STAT_H_FOUND-NOTFOUND")
 293   FIND_FILE(HAVE_SYS_STAT_H sys/stat.h)
 294   SET(HAS_SYS_STAT_H 1)
 295 ENDIF()
 296 FIND_FILE(HAVE_SYS_TYPES_H_FOUND sys/types.h)
 297 IF(NOT HAVE_SYS_TYPES_H_FOUND STREQUAL "HAVE_SYS_TYPES_H_FOUND-NOTFOUND")
 298   FIND_FILE(HAVE_SYS_TYPES_H sys/types.h)
 299   SET(HAS_SYS_TYPES_H 1)
 300 ENDIF()
 301 FIND_FILE(HAVE_UNISTD_H_FOUND unistd.h)
 302 IF(NOT HAVE_UNISTD_H_FOUND STREQUAL "HAVE_UNISTD_H_FOUND-NOTFOUND")
 303   FIND_FILE(HAVE_UNISTD_H unistd.h)
 304   SET(HAS_UNISTD_H 1)
 305 ENDIF()
 306 #
 307 # Does the system have png library installed ?
 308 #
 309 FIND_PACKAGE(PNG)
 310 #
 311 IF(PNG_FOUND)
 312   SET(HAVE_PNG_H 1)
 313   SET(HAVE_LIBPNG 1)
 314 ENDIF()
 315 #
 316 # Does the system have tiff library installed ?
 317 #
 318 FIND_PACKAGE(TIFF)
 319 #
 320 IF(TIFF_FOUND)
 321   SET(HAVE_TIFF_H 1)
 322   SET(HAVE_LIBTIFF 1)
 323 ENDIF()
 324 #
 325 #
 326 # Does the system have lcms library installed ?
 327 #
 328 SET(LCMS_LIB "")
 329 FIND_FILE(LCMS2_HEADER_FOUND lcms2.h)
 330 #
 331 IF(LCMS2_HEADER_FOUND STREQUAL "LCMS2_HEADER_FOUND-NOTFOUND")
 332  SET(LCMS2_HEADER_FOUND "")
 333 ENDIF()
 334 IF(LCMS2_HEADER_FOUND)
 335  FIND_PATH(LCMS_INCLUDE_DIR  lcms2.h)
 336  IF(UNIX OR CYGWIN)
 337    FIND_LIBRARY(HAVE_LIBLCMS2 lcms2)
 338  ELSE()
 339    FIND_LIBRARY(HAVE_LIBLCMS2 lcms2_static.lib)
 340  ENDIF()
 341  IF(HAVE_LIBLCMS2 STREQUAL "HAVE_LIBLCMS2-NOTFOUND")
 342   SET(HAVE_LIBLCMS2 "")
 343  ENDIF()
 344  IF(HAVE_LIBLCMS2)
 345   SET(LCMS_LIB "${HAVE_LIBLCMS2}")
 346   SET(HAVE_LCMS2_LIB 1)
 347   SET(HAVE_LCMS2_H 1)
 348  ENDIF()
 349 ENDIF()
 350 IF(NOT LCMS2_HEADER_FOUND)
 351  FIND_FILE(LCMS1_HEADER_FOUND lcms.h)
 352  IF(LCMS1_HEADER_FOUND STREQUAL "LCMS1_HEADER_FOUND-NOTFOUND")
 353   SET(LCMS1_HEADER_FOUND "")
 354  ENDIF()
 355  IF(LCMS1_HEADER_FOUND)
 356   FIND_PATH(LCMS_INCLUDE_DIR  lcms.h)
 357   FIND_LIBRARY(HAVE_LIBLCMS1 lcms)
 358   IF(HAVE_LIBLCMS1 STREQUAL "HAVE_LIBLCMS1-NOTFOUND")
 359    SET(HAVE_LIBLCMS1 "")
 360   ENDIF()
 361   IF(HAVE_LIBLCMS1)
 362    SET(LCMS_LIB "${HAVE_LIBLCMS1}")
 363    SET(HAVE_LCMS1_LIB 1)
 364    SET(HAVE_LCMS1_H 1)
 365   ENDIF()
 366  ENDIF()
 367 ENDIF()
 368 #
 369 # generate opj_config.h
 370 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_configh.cmake.in"
 371   "${OPENJPEG_BINARY_DIR}/opj_config.h"
 372   @ONLY
 373 )
 374