configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32
  33 api=""
  34 req=""
  35 use_asio=""
  36
  37
  38 # configure flags
  39 AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
  40 AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support (mac and linux only)])])
  41 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
  42 AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (linux only)])])
  43 AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
  44 AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
  45 AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
  46 AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
  47 AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])
  48
  49 # Check version number coherency between RtAudio.h and configure.ac
  50 AC_MSG_CHECKING([that version numbers are coherent])
  51 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  52 AS_IF(
  53    [test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],
  54    [AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])]
  55 )
  56 # Enable some nice automake features if they are available
  57 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  59
  60 # Fill GXX with something before test.
  61 GXX="no"
  62 # if the user did not provide any CXXFLAGS, we can override them
  63 AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
  64 AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])
  65
  66 dnl Check for pkg-config program, used for configuring some libraries.
  67 m4_define_default([PKG_PROG_PKG_CONFIG],
  68 [AC_MSG_CHECKING([pkg-config])
  69 AC_MSG_RESULT([no])])
  70
  71 PKG_PROG_PKG_CONFIG
  72
  73 dnl If the pkg-config autoconf support isn't installed, define its
  74 dnl autoconf macro to disable any packages depending on it.
  75 m4_define_default([PKG_CHECK_MODULES],
  76 [AC_MSG_CHECKING([$1])
  77 AC_MSG_RESULT([no])
  78 $4])
  79
  80
  81 # Checks for programs.
  82 AC_PROG_CXX(g++ CC c++ cxx)
  83 AM_PROG_AR
  84 AC_PATH_PROG(AR, ar, no)
  85 AS_IF([test "x${AR}" = "xno" ], [
  86     AC_MSG_ERROR([Could not find ar - needed to create a library])
  87 ])
  88
  89 # Initialize libtool
  90 LT_INIT([win32-dll])
  91 AC_CONFIG_MACRO_DIR([m4])
  92
  93 # Checks for header files.
  94 AC_HEADER_STDC
  95 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  96
  97 # Check compiler and use -Wall if gnu
  98 AS_IF([test "x${GXX}" = "xyes" ], [
  99   CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
 100   AS_IF([ test "x${enable_debug}" = "xyes" ], [
 101     # Add -Werror in debug mode
 102     CXXFLAGS="-Werror ${CXXFLAGS}"
 103   ], [
 104     # hide private symbols in non-debug mode
 105     visibility="-fvisibility=hidden"
 106   ])
 107 ])
 108
 109 # Check for debug
 110 AC_MSG_CHECKING(whether to compile debug version)
 111 debugflags=""
 112 AS_CASE([${enable_debug}],
 113   [ yes ], [
 114     AC_MSG_RESULT([yes])
 115     AC_DEFINE([__RTAUDIO_DEBUG__])
 116     debugflags="${debugflags} -g -O0"
 117     object_path=Debug
 118   ],
 119   [ no ], [
 120     AC_MSG_RESULT([no!])
 121     debugflags="${debugflags} -O3"
 122   ], [
 123     AC_MSG_RESULT([no])
 124   ])
 125
 126 # For debugging and optimization ... overwrite default because it has both -g and -O2
 127 AS_IF([test "x$debugflags" != x],
 128   AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
 129   AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
 130   )
 131
 132
 133 # Checks for functions
 134 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
 135
 136 # Checks for doxygen
 137 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 138 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )
 139
 140 # Copy doc files to build dir if necessary
 141 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 142 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 143 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 144 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 145 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 146 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 147 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 148 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 149 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 150 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 151 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 152 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 153 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 154 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 155 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 156 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 157 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 158
 159 # Checks for package options and external software
 160 AC_CANONICAL_HOST
 161
 162 AC_MSG_CHECKING(for audio API)
 163
 164 AS_IF([test "x$with_jack" = "xyes"], [
 165   AC_MSG_RESULT(using JACK)
 166   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR(JACK support requires the jack library!))
 167   api="$api -D__UNIX_JACK__"
 168 ])
 169
 170
 171 AS_CASE([$host],
 172   [*-*-netbsd*],
 173   AS_IF([test "x$api" = "x"], [
 174     AC_MSG_RESULT(using OSS)
 175     api="$api -D__LINUX_OSS__"
 176     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 177     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 178   ]),
 179   [*-*-freebsd*],
 180   AS_IF([test "x$api" = "x"], [
 181     AC_MSG_RESULT(using OSS)
 182     api="$api -D__LINUX_OSS__"
 183     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 184     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 185   ]),
 186   [*-*-linux*], [
 187   # Look for ALSA flag
 188   AS_IF([test "x$with_alsa" = "xyes"], [
 189     AC_MSG_RESULT(using ALSA)
 190     api="$api -D__LINUX_ALSA__"
 191     req="$req alsa"
 192     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 193   ])
 194   # Look for PULSE flag
 195   AS_IF([test "x$with_pulse" = "xyes"], [
 196     AC_MSG_RESULT(using PulseAudio)
 197     api="$api -D__LINUX_PULSE__"
 198     req="$req libpulse-simple"
 199     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR(PulseAudio support requires the pulse-simple library!))
 200   ])
 201
 202   # Look for OSS flag
 203   AS_IF([test "x$with_oss" = "xyes"], [
 204     AC_MSG_RESULT(using OSS)
 205     api="$api -D__LINUX_OSS__"
 206   ])
 207
 208   # If no audio api flags specified, use ALSA
 209   AS_IF([test "x$api" = "x" ], [
 210     AC_MSG_RESULT(using ALSA)
 211     api="${api} -D__LINUX_ALSA__"
 212     req="${req} alsa"
 213     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 214   ])
 215   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 216   ],
 217   [*-apple*],[
 218   # Look for Core flag
 219   AS_IF([test "x$with_core" = "xyes"], [
 220     AC_MSG_RESULT(using CoreAudio)
 221     api="$api -D__MACOSX_CORE__"
 222     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR(CoreAudio header files not found!)] )
 223     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
 224   ])
 225   # If no audio api flags specified, use CoreAudio
 226   AS_IF([test "x$api" = "x" ], [
 227     AC_MSG_RESULT(using CoreAudio)
 228     api="${api} -D__MACOSX_CORE__"
 229     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 230       [],
 231       [AC_MSG_ERROR(CoreAudio header files not found!)] )
 232     LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
 233   ])
 234   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 235   ],
 236   [*-mingw32*],[
 237   AS_IF([test "x$with_asio" = "xyes" ], [
 238     AC_MSG_RESULT(using ASIO)
 239     api="$api -D__WINDOWS_ASIO__"
 240     use_asio=yes
 241   ])
 242   # Look for DirectSound flag
 243   AS_IF([test "x$with_ds" = "xyes" ], [
 244     AC_MSG_RESULT(using DirectSound)
 245     api="$api -D__WINDOWS_DS__"
 246     LIBS="-ldsound -lwinmm $LIBS"
 247   ])
 248   # Look for WASAPI flag
 249   AS_IF([test "x$with_wasapi" = "xyes"], [
 250     AC_MSG_RESULT(using WASAPI)
 251     api="$api -D__WINDOWS_WASAPI__"
 252     LIBS="-lwinmm -luuid -lksuser $LIBS"
 253   ])
 254   # If no audio api flags specified, use DS
 255   AS_IF([test "x$api" = "x" ], [
 256     AC_MSG_RESULT(using DirectSound)
 257     api="$api -D__WINDOWS_DS__"
 258     LIBS="-ldsound -lwinmm $LIBS"
 259   ])
 260   LIBS="-lole32 $LIBS"
 261   ],[
 262   # Default case for unknown realtime systems.
 263   AC_MSG_ERROR(Unknown system type for realtime support!)
 264   ]
 265 )
 266
 267 AM_CONDITIONAL( ASIO, [test "x${use_asio}" = "xyes" ])
 268
 269 CPPFLAGS="$CPPFLAGS $api"
 270
 271 AC_OUTPUT