configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32
  33 api=""
  34 req=""
  35 use_asio=""
  36
  37
  38 # configure flags
  39 AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
  40 AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support (mac and linux only)])])
  41 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
  42 AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (linux only)])])
  43 AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
  44 AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
  45 AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
  46 AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
  47 AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])
  48
  49 # Check version number coherency between RtAudio.h and configure.ac
  50 AC_MSG_CHECKING([that version numbers are coherent])
  51 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  52 AS_IF([test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],[
  53    AC_MSG_RESULT([no])
  54    AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])
  55    ],[
  56    AC_MSG_RESULT([yes])
  57 ])
  58 # Enable some nice automake features if they are available
  59 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  60 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  61
  62 # Fill GXX with something before test.
  63 GXX="no"
  64 # if the user did not provide any CXXFLAGS, we can override them
  65 AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
  66 AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])
  67
  68 # Checks for programs.
  69 AC_PROG_CXX(g++ CC c++ cxx)
  70 AM_PROG_AR
  71 AC_PATH_PROG(AR, ar, no)
  72 AS_IF([test "x${AR}" = "xno" ], [
  73     AC_MSG_ERROR([Could not find ar - needed to create a library])
  74 ])
  75
  76 # Initialize libtool
  77 LT_INIT([win32-dll])
  78 AC_CONFIG_MACRO_DIR([m4])
  79
  80 # Checks for header files.
  81 AC_HEADER_STDC
  82 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  83
  84 # Check compiler and use -Wall if gnu
  85 AS_IF([test "x${GXX}" = "xyes" ], [
  86   CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
  87   AS_IF([ test "x${enable_debug}" = "xyes" ], [
  88     # Add -Werror in debug mode
  89     CXXFLAGS="-Werror ${CXXFLAGS}"
  90   ], [
  91     # hide private symbols in non-debug mode
  92     visibility="-fvisibility=hidden"
  93   ])
  94 ])
  95
  96 # Check for debug
  97 AC_MSG_CHECKING([whether to compile debug version])
  98 debugflags=""
  99 AS_CASE([${enable_debug}],
 100   [ yes ], [
 101     AC_MSG_RESULT([yes])
 102     AC_DEFINE([__RTAUDIO_DEBUG__])
 103     debugflags="${debugflags} -g -O0"
 104     object_path=Debug
 105   ],
 106   [ no ], [
 107     AC_MSG_RESULT([no!])
 108     debugflags="${debugflags} -O3"
 109   ], [
 110     AC_MSG_RESULT([no])
 111   ])
 112
 113 # For debugging and optimization ... overwrite default because it has both -g and -O2
 114 AS_IF([test "x$debugflags" != x],
 115   AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
 116   AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
 117   )
 118
 119
 120 # Checks for functions
 121 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
 122
 123 # Checks for doxygen
 124 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 125 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )
 126
 127 # Copy doc files to build dir if necessary
 128 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 129 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 130 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 131 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 132 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 133 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 134 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 135 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 136 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 137 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 138 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 139 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 140 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 141 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 142 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 143 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 144 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 145
 146 # Checks for package options and external software
 147 AC_CANONICAL_HOST
 148
 149 AC_MSG_CHECKING([for audio API])
 150
 151 AS_IF([test "x$with_jack" = "xyes"], [
 152   AC_MSG_RESULT([using JACK])
 153   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR([JACK support requires the jack library!]))
 154   api="$api -D__UNIX_JACK__"
 155 ])
 156
 157
 158 AS_CASE([$host],
 159   [*-*-netbsd*],
 160   AS_IF([test "x$api" = "x"], [
 161     AC_MSG_RESULT([using OSS])
 162     api="$api -D__LINUX_OSS__"
 163     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 164     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 165   ]),
 166   [*-*-freebsd*],
 167   AS_IF([test "x$api" = "x"], [
 168     AC_MSG_RESULT([using OSS])
 169     api="$api -D__LINUX_OSS__"
 170     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 171     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 172   ]),
 173   [*-*-linux*], [
 174   # Look for ALSA flag
 175   AS_IF([test "x$with_alsa" = "xyes"], [
 176     AC_MSG_RESULT([using ALSA])
 177     api="$api -D__LINUX_ALSA__"
 178     req="$req alsa"
 179     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
 180   ])
 181   # Look for PULSE flag
 182   AS_IF([test "x$with_pulse" = "xyes"], [
 183     AC_MSG_RESULT([using PulseAudio])
 184     api="$api -D__LINUX_PULSE__"
 185     req="$req libpulse-simple"
 186     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR([PulseAudio support requires the pulse-simple library!]))
 187   ])
 188
 189   # Look for OSS flag
 190   AS_IF([test "x$with_oss" = "xyes"], [
 191     AC_MSG_RESULT([using OSS])
 192     api="$api -D__LINUX_OSS__"
 193   ])
 194
 195   # If no audio api flags specified, use ALSA
 196   AS_IF([test "x$api" = "x" ], [
 197     AC_MSG_RESULT([using ALSA])
 198     api="${api} -D__LINUX_ALSA__"
 199     req="${req} alsa"
 200     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
 201   ])
 202   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 203   ],
 204   [*-apple*],[
 205   # Look for Core flag
 206   AS_IF([test "x$with_core" = "xyes"], [
 207     AC_MSG_RESULT([using CoreAudio])
 208     api="$api -D__MACOSX_CORE__"
 209     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR([CoreAudio header files not found!])] )
 210     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
 211   ])
 212   # If no audio api flags specified, use CoreAudio
 213   AS_IF([test "x$api" = "x" ], [
 214     AC_MSG_RESULT([using CoreAudio])
 215     api="${api} -D__MACOSX_CORE__"
 216     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 217       [],
 218       [AC_MSG_ERROR([CoreAudio header files not found!])] )
 219     LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
 220   ])
 221   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 222   ],
 223   [*-mingw32*],[
 224   AS_IF([test "x$with_asio" = "xyes" ], [
 225     AC_MSG_RESULT([using ASIO])
 226     api="$api -D__WINDOWS_ASIO__"
 227     use_asio=yes
 228   ])
 229   # Look for DirectSound flag
 230   AS_IF([test "x$with_ds" = "xyes" ], [
 231     AC_MSG_RESULT([using DirectSound])
 232     api="$api -D__WINDOWS_DS__"
 233     LIBS="-ldsound -lwinmm $LIBS"
 234   ])
 235   # Look for WASAPI flag
 236   AS_IF([test "x$with_wasapi" = "xyes"], [
 237     AC_MSG_RESULT([using WASAPI])
 238     api="$api -D__WINDOWS_WASAPI__"
 239     LIBS="-lwinmm -luuid -lksuser $LIBS"
 240   ])
 241   # If no audio api flags specified, use DS
 242   AS_IF([test "x$api" = "x" ], [
 243     AC_MSG_RESULT([using DirectSound])
 244     api="$api -D__WINDOWS_DS__"
 245     LIBS="-ldsound -lwinmm $LIBS"
 246   ])
 247   LIBS="-lole32 $LIBS"
 248   ],[
 249   AC_MSG_RESULT([none])
 250   # Default case for unknown realtime systems.
 251   AC_MSG_ERROR([Unknown system type for realtime support!])
 252   ]
 253 )
 254
 255 AM_CONDITIONAL( ASIO, [test "x${use_asio}" = "xyes" ])
 256
 257 CPPFLAGS="$CPPFLAGS $api"
 258
 259 AC_OUTPUT