configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32 AC_SUBST(visibility)
  33
  34 api=""
  35 req=""
  36 use_asio=""
  37
  38
  39 # configure flags
  40 AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
  41 AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support (mac and linux only)])])
  42 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
  43 AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (linux only)])])
  44 AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
  45 AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
  46 AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
  47 AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
  48 AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])
  49
  50 # Check version number coherency between RtAudio.h and configure.ac
  51 AC_MSG_CHECKING([that version numbers are coherent])
  52 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  53 AS_IF([test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],[
  54    AC_MSG_RESULT([no])
  55    AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])
  56    ],[
  57    AC_MSG_RESULT([yes])
  58 ])
  59 # Enable some nice automake features if they are available
  60 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  61 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  62
  63 # Fill GXX with something before test.
  64 GXX="no"
  65 # if the user did not provide any CXXFLAGS, we can override them
  66 AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
  67 AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])
  68
  69 # Checks for programs.
  70 AC_PROG_CXX(g++ CC c++ cxx)
  71 AM_PROG_AR
  72 AC_PATH_PROG(AR, ar, no)
  73 AS_IF([test "x${AR}" = "xno" ], [
  74     AC_MSG_ERROR([Could not find ar - needed to create a library])
  75 ])
  76
  77 # Initialize libtool
  78 LT_INIT([win32-dll])
  79 AC_CONFIG_MACRO_DIR([m4])
  80
  81 # Checks for header files.
  82 AC_HEADER_STDC
  83 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  84
  85 # Check compiler and use -Wall if gnu
  86 AS_IF([test "x${GXX}" = "xyes" ], [
  87   CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
  88   AS_IF([ test "x${enable_debug}" = "xyes" ], [
  89     # Add -Werror in debug mode
  90     CXXFLAGS="-Werror ${CXXFLAGS}"
  91   ], [
  92     # hide private symbols in non-debug mode
  93     visibility="-fvisibility=hidden"
  94   ])
  95 ])
  96
  97 # Check for debug
  98 AC_MSG_CHECKING([whether to compile debug version])
  99 debugflags=""
 100 AS_CASE([${enable_debug}],
 101   [ yes ], [
 102     AC_MSG_RESULT([yes])
 103     AC_DEFINE([__RTAUDIO_DEBUG__])
 104     debugflags="${debugflags} -g -O0"
 105     object_path=Debug
 106   ],
 107   [ no ], [
 108     AC_MSG_RESULT([no!])
 109     debugflags="${debugflags} -O3"
 110   ], [
 111     AC_MSG_RESULT([no])
 112   ])
 113
 114 # For debugging and optimization ... overwrite default because it has both -g and -O2
 115 AS_IF([test "x$debugflags" != x],
 116   AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
 117   AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
 118   )
 119
 120
 121 # Checks for functions
 122 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
 123
 124 # Checks for doxygen
 125 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 126 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )
 127
 128 # Copy doc files to build dir if necessary
 129 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 130 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 131 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 132 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 133 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 134 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 135 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 136 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 137 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 138 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 139 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 140 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 141 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 142 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 143 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 144 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 145 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 146
 147 # Checks for package options and external software
 148 AC_CANONICAL_HOST
 149
 150 AC_MSG_CHECKING([for audio API])
 151
 152 AS_IF([test "x$with_jack" = "xyes"], [
 153   AC_MSG_RESULT([using JACK])
 154   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR([JACK support requires the jack library!]))
 155   api="$api -D__UNIX_JACK__"
 156 ])
 157
 158
 159 AS_CASE([$host],
 160   [*-*-netbsd*],
 161   AS_IF([test "x$api" = "x"], [
 162     AC_MSG_RESULT([using OSS])
 163     api="$api -D__LINUX_OSS__"
 164     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 165     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 166   ]),
 167   [*-*-freebsd*],
 168   AS_IF([test "x$api" = "x"], [
 169     AC_MSG_RESULT([using OSS])
 170     api="$api -D__LINUX_OSS__"
 171     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 172     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 173   ]),
 174   [*-*-linux*], [
 175   # Look for ALSA flag
 176   AS_IF([test "x$with_alsa" = "xyes"], [
 177     AC_MSG_RESULT([using ALSA])
 178     api="$api -D__LINUX_ALSA__"
 179     req="$req alsa"
 180     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
 181   ])
 182   # Look for PULSE flag
 183   AS_IF([test "x$with_pulse" = "xyes"], [
 184     AC_MSG_RESULT([using PulseAudio])
 185     api="$api -D__LINUX_PULSE__"
 186     req="$req libpulse-simple"
 187     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR([PulseAudio support requires the pulse-simple library!]))
 188   ])
 189
 190   # Look for OSS flag
 191   AS_IF([test "x$with_oss" = "xyes"], [
 192     AC_MSG_RESULT([using OSS])
 193     api="$api -D__LINUX_OSS__"
 194   ])
 195
 196   # If no audio api flags specified, use ALSA
 197   AS_IF([test "x$api" = "x" ], [
 198     AC_MSG_RESULT([using ALSA])
 199     api="${api} -D__LINUX_ALSA__"
 200     req="${req} alsa"
 201     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
 202   ])
 203   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 204   ],
 205   [*-apple*],[
 206   # Look for Core flag
 207   AS_IF([test "x$with_core" = "xyes"], [
 208     AC_MSG_RESULT([using CoreAudio])
 209     api="$api -D__MACOSX_CORE__"
 210     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR([CoreAudio header files not found!])] )
 211     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
 212   ])
 213   # If no audio api flags specified, use CoreAudio
 214   AS_IF([test "x$api" = "x" ], [
 215     AC_MSG_RESULT([using CoreAudio])
 216     api="${api} -D__MACOSX_CORE__"
 217     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 218       [],
 219       [AC_MSG_ERROR([CoreAudio header files not found!])] )
 220     LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
 221   ])
 222   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
 223   ],
 224   [*-mingw32*],[
 225   AS_IF([test "x$with_asio" = "xyes" ], [
 226     AC_MSG_RESULT([using ASIO])
 227     api="$api -D__WINDOWS_ASIO__"
 228     use_asio=yes
 229   ])
 230   # Look for DirectSound flag
 231   AS_IF([test "x$with_ds" = "xyes" ], [
 232     AC_MSG_RESULT([using DirectSound])
 233     api="$api -D__WINDOWS_DS__"
 234     LIBS="-ldsound -lwinmm $LIBS"
 235   ])
 236   # Look for WASAPI flag
 237   AS_IF([test "x$with_wasapi" = "xyes"], [
 238     AC_MSG_RESULT([using WASAPI])
 239     api="$api -D__WINDOWS_WASAPI__"
 240     LIBS="-lwinmm -luuid -lksuser $LIBS"
 241   ])
 242   # If no audio api flags specified, use DS
 243   AS_IF([test "x$api" = "x" ], [
 244     AC_MSG_RESULT([using DirectSound])
 245     api="$api -D__WINDOWS_DS__"
 246     LIBS="-ldsound -lwinmm $LIBS"
 247   ])
 248   LIBS="-lole32 $LIBS"
 249   ],[
 250   AC_MSG_RESULT([none])
 251   # Default case for unknown realtime systems.
 252   AC_MSG_ERROR([Unknown system type for realtime support!])
 253   ]
 254 )
 255
 256 AM_CONDITIONAL( ASIO, [test "x${use_asio}" = "xyes" ])
 257
 258 CPPFLAGS="$CPPFLAGS $api"
 259
 260 AC_OUTPUT