src/lib/openjp2/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 #
   4 install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/opj_config.h
   5  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR} COMPONENT Headers)
   6
   7 include_directories(
   8   ${${OPENJPEG_NAMESPACE}_BINARY_DIR}/src/lib/openjp2 # opj_config.h and opj_config_private.h
   9 )
  10 # Defines the source code for the library
  11 set(OPENJPEG_SRCS
  12   ${CMAKE_CURRENT_SOURCE_DIR}/thread.c
  13   ${CMAKE_CURRENT_SOURCE_DIR}/thread.h
  14   ${CMAKE_CURRENT_SOURCE_DIR}/bio.c
  15   ${CMAKE_CURRENT_SOURCE_DIR}/bio.h
  16   ${CMAKE_CURRENT_SOURCE_DIR}/cio.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/cio.h
  18   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.h
  20   ${CMAKE_CURRENT_SOURCE_DIR}/event.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/event.h
  22   ${CMAKE_CURRENT_SOURCE_DIR}/ht_dec.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/image.c
  24   ${CMAKE_CURRENT_SOURCE_DIR}/image.h
  25   ${CMAKE_CURRENT_SOURCE_DIR}/invert.c
  26   ${CMAKE_CURRENT_SOURCE_DIR}/invert.h
  27   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.c
  28   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.h
  29   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.c
  30   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.h
  31   ${CMAKE_CURRENT_SOURCE_DIR}/mct.c
  32   ${CMAKE_CURRENT_SOURCE_DIR}/mct.h
  33   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.c
  34   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.h
  35   ${CMAKE_CURRENT_SOURCE_DIR}/mqc_inl.h
  36   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.c
  37   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.h
  38   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.c
  39   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.h
  40   ${CMAKE_CURRENT_SOURCE_DIR}/pi.c
  41   ${CMAKE_CURRENT_SOURCE_DIR}/pi.h
  42   ${CMAKE_CURRENT_SOURCE_DIR}/t1.c
  43   ${CMAKE_CURRENT_SOURCE_DIR}/t1.h
  44   ${CMAKE_CURRENT_SOURCE_DIR}/t2.c
  45   ${CMAKE_CURRENT_SOURCE_DIR}/t2.h
  46   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.c
  47   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.h
  48   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.c
  49   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.h
  50   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.c
  51   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.h
  52   ${CMAKE_CURRENT_SOURCE_DIR}/opj_codec.h
  53   ${CMAKE_CURRENT_SOURCE_DIR}/opj_includes.h
  54   ${CMAKE_CURRENT_SOURCE_DIR}/opj_intmath.h
  55   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.c
  56   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.h
  57   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.c
  58   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.h
  59 )
  60 if(BUILD_JPIP)
  61   add_definitions(-DUSE_JPIP)
  62   set(OPENJPEG_SRCS
  63     ${OPENJPEG_SRCS}
  64     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.c
  65     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.h
  66     ${CMAKE_CURRENT_SOURCE_DIR}/phix_manager.c
  67     ${CMAKE_CURRENT_SOURCE_DIR}/ppix_manager.c
  68     ${CMAKE_CURRENT_SOURCE_DIR}/thix_manager.c
  69     ${CMAKE_CURRENT_SOURCE_DIR}/tpix_manager.c
  70     ${CMAKE_CURRENT_SOURCE_DIR}/indexbox_manager.h
  71   )
  72 endif()
  73
  74 option(OPJ_DISABLE_TPSOT_FIX "Disable TPsot==TNsot fix. See https://github.com/uclouvain/openjpeg/issues/254." OFF)
  75 if(OPJ_DISABLE_TPSOT_FIX)
  76   add_definitions(-DOPJ_DISABLE_TPSOT_FIX)
  77 endif()
  78
  79 # Special case for old i586-mingw32msvc-gcc cross compiler
  80 if(NOT WIN32 AND CMAKE_COMPILER_IS_GNUCC AND CMAKE_C_COMPILER MATCHES ".*mingw32msvc.*" )
  81   set(WIN32 YES)
  82 endif()
  83
  84 # Build the library
  85 if(WIN32)
  86   if(BUILD_SHARED_LIBS)
  87     add_definitions(-DOPJ_EXPORTS)
  88   else()
  89     add_definitions(-DOPJ_STATIC)
  90   endif()
  91   add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
  92   set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
  93 else()
  94   if(BUILD_SHARED_LIBS AND BUILD_STATIC_LIBS)
  95     # Builds both static and dynamic libs
  96     add_library(${OPENJPEG_LIBRARY_NAME} SHARED ${OPENJPEG_SRCS})
  97     add_library(openjp2_static STATIC ${OPENJPEG_SRCS})
  98     set_target_properties(openjp2_static PROPERTIES OUTPUT_NAME ${OPENJPEG_LIBRARY_NAME})
  99     set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME} openjp2_static)
 100     target_include_directories(openjp2_static PUBLIC $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR}>)
 101   else()
 102     add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
 103     set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
 104   endif()
 105 endif()
 106
 107 target_include_directories(${OPENJPEG_LIBRARY_NAME} PUBLIC $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR}>)
 108 if(UNIX)
 109   target_link_libraries(${OPENJPEG_LIBRARY_NAME} m)
 110 endif()
 111 set_target_properties(${OPENJPEG_LIBRARY_NAME} PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
 112 target_compile_options(${OPENJPEG_LIBRARY_NAME} PRIVATE ${OPENJP2_COMPILE_OPTIONS})
 113
 114 # Install library
 115 install(TARGETS ${INSTALL_LIBS}
 116   EXPORT OpenJPEGTargets
 117   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT Applications
 118   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT Libraries
 119   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT Libraries
 120 )
 121
 122 # Install includes files
 123 install(FILES openjpeg.h
 124   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR} COMPONENT Headers
 125 )
 126
 127 if(BUILD_DOC)
 128 # install man page of the library
 129 install(
 130   FILES       ${OPENJPEG_SOURCE_DIR}/doc/man/man3/libopenjp2.3
 131   DESTINATION ${CMAKE_INSTALL_MANDIR}/man3)
 132 endif()
 133
 134 if(BUILD_LUTS_GENERATOR)
 135 # internal utility to generate t1_luts.h and t1_ht_luts.h (part of the jp2 lib)
 136 # no need to install:
 137   add_executable(t1_generate_luts t1_generate_luts.c t1_ht_generate_luts.c)
 138   if(UNIX)
 139     target_link_libraries(t1_generate_luts m)
 140   endif()
 141 endif()
 142
 143 # Experimental option; let's how cppcheck performs
 144 # Implementation details:
 145 # I could not figure out how to easily upload a file to CDash. Instead simply
 146 # pretend cppcheck is part of the Build step. Technically cppcheck can even
 147 # output gcc formatted error/warning report
 148 # Another implementation detail: I could not redirect error to the error
 149 # catching mechanism something is busted in cmake 2.8.5, I had to use the
 150 # warning regex to catch them.
 151 if(OPENJPEG_CPPCHECK)
 152   find_package(CPPCHECK REQUIRED)
 153   foreach(f ${OPENJPEG_SRCS})
 154     # cppcheck complains about too many configuration, pretend to be WIN32:
 155     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME}
 156       COMMAND ${CPPCHECK_EXECUTABLE} -DWIN32 ${f})
 157   endforeach()
 158 endif()
 159
 160 if(OPJ_USE_DSYMUTIL)
 161   if(BUILD_SHARED_LIBS)
 162     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME} POST_BUILD
 163     COMMAND "dsymutil" "$<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 164     COMMENT "dsymutil $<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 165     DEPENDS ${OPENJPEG_LIBRARY_NAME})
 166   endif()
 167 endif()
 168
 169 #################################################################################
 170 # threading configuration
 171 #################################################################################
 172 set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 173
 174 option(OPJ_USE_THREAD "Build with thread/mutex support " ON)
 175 if(NOT OPJ_USE_THREAD)
 176    add_definitions( -DMUTEX_stub)
 177 endif(NOT OPJ_USE_THREAD)
 178
 179 find_package(Threads QUIET)
 180
 181 if(OPJ_USE_THREAD AND WIN32 AND NOT Threads_FOUND )
 182     add_definitions( -DMUTEX_win32)
 183     set(Threads_FOUND YES)
 184 endif()
 185
 186 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 187    add_definitions( -DMUTEX_win32)
 188 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 189
 190 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 191    add_definitions( -DMUTEX_pthread)
 192 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 193
 194 if(OPJ_USE_THREAD AND NOT Threads_FOUND)
 195   message(FATAL_ERROR "No thread library found and thread/mutex support is required by OPJ_USE_THREAD option")
 196 endif(OPJ_USE_THREAD AND NOT Threads_FOUND)
 197
 198 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 199    TARGET_LINK_LIBRARIES(${OPENJPEG_LIBRARY_NAME} ${CMAKE_THREAD_LIBS_INIT})
 200 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 201
 202 if(BUILD_UNIT_TESTS AND UNIX)
 203     add_executable(bench_dwt bench_dwt.c)
 204     if(UNIX)
 205         target_link_libraries(bench_dwt m ${OPENJPEG_LIBRARY_NAME})
 206     endif()
 207     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 208         target_link_libraries(bench_dwt ${CMAKE_THREAD_LIBS_INIT})
 209     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 210
 211     add_executable(test_sparse_array test_sparse_array.c)
 212     if(UNIX)
 213         target_link_libraries(test_sparse_array m ${OPENJPEG_LIBRARY_NAME})
 214     endif()
 215     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 216         target_link_libraries(test_sparse_array ${CMAKE_THREAD_LIBS_INIT})
 217     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 218 endif(BUILD_UNIT_TESTS AND UNIX)