src/lib/openjpip/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 add_definitions(-DUSE_JPIP)
   4
   5 include_directories(
   6   ${CMAKE_CURRENT_SOURCE_DIR}
   7   ${OPENJPEG_BINARY_DIR}/src/lib/openjp2 # opj_config.h
   8   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2
   9   ${FCGI_INCLUDE_DIRS}
  10   ${CURL_INCLUDE_DIRS}
  11 )
  12
  13 # Defines the source code for the library
  14 set(OPENJPIP_SRCS
  15   ${CMAKE_CURRENT_SOURCE_DIR}/boxheader_manager.c
  16   ${CMAKE_CURRENT_SOURCE_DIR}/codestream_manager.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/imgreg_manager.c
  18   ${CMAKE_CURRENT_SOURCE_DIR}/marker_manager.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/msgqueue_manager.c
  20   ${CMAKE_CURRENT_SOURCE_DIR}/box_manager.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/faixbox_manager.c
  22   ${CMAKE_CURRENT_SOURCE_DIR}/index_manager.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/metadata_manager.c
  24   ${CMAKE_CURRENT_SOURCE_DIR}/placeholder_manager.c
  25   ${CMAKE_CURRENT_SOURCE_DIR}/byte_manager.c
  26   ${CMAKE_CURRENT_SOURCE_DIR}/ihdrbox_manager.c
  27   ${CMAKE_CURRENT_SOURCE_DIR}/manfbox_manager.c
  28   ${CMAKE_CURRENT_SOURCE_DIR}/mhixbox_manager.c
  29   ${CMAKE_CURRENT_SOURCE_DIR}/target_manager.c
  30   ${CMAKE_CURRENT_SOURCE_DIR}/cachemodel_manager.c
  31   ${CMAKE_CURRENT_SOURCE_DIR}/j2kheader_manager.c
  32   ${CMAKE_CURRENT_SOURCE_DIR}/jp2k_encoder.c
  33   ${CMAKE_CURRENT_SOURCE_DIR}/openjpip.c
  34   ${CMAKE_CURRENT_SOURCE_DIR}/query_parser.c
  35   ${CMAKE_CURRENT_SOURCE_DIR}/channel_manager.c
  36   ${CMAKE_CURRENT_SOURCE_DIR}/session_manager.c
  37   ${CMAKE_CURRENT_SOURCE_DIR}/jpip_parser.c
  38   ${CMAKE_CURRENT_SOURCE_DIR}/sock_manager.c
  39   )
  40
  41 set(SERVER_SRCS
  42   ${CMAKE_CURRENT_SOURCE_DIR}/auxtrans_manager.c
  43   )
  44
  45 set(LOCAL_SRCS
  46   ${CMAKE_CURRENT_SOURCE_DIR}/jp2k_decoder.c
  47   ${CMAKE_CURRENT_SOURCE_DIR}/imgsock_manager.c
  48   ${CMAKE_CURRENT_SOURCE_DIR}/jpipstream_manager.c
  49   ${CMAKE_CURRENT_SOURCE_DIR}/cache_manager.c
  50   ${CMAKE_CURRENT_SOURCE_DIR}/dec_clientmsg_handler.c
  51   )
  52
  53 # Build the library
  54 if(WIN32)
  55   if(BUILD_SHARED_LIBS)
  56     add_definitions(-DOPJ_EXPORTS)
  57   else()
  58     add_definitions(-DOPJ_STATIC)
  59   endif()
  60 endif()
  61 add_library(openjpip ${OPENJPIP_SRCS} ${LOCAL_SRCS})
  62 set_target_properties(openjpip
  63   PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
  64 target_compile_options(openjpip PRIVATE ${OPENJPEG_LIBRARY_COMPILE_OPTIONS})
  65 target_link_libraries(openjpip ${OPENJPEG_LIBRARY_NAME})
  66 if(WIN32)
  67   # add Winsock on windows+mingw
  68   target_link_libraries(openjpip ws2_32)
  69 endif()
  70
  71 # Install library
  72 install(TARGETS openjpip
  73   EXPORT OpenJPEGTargets
  74   RUNTIME DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  75   LIBRARY DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  76   ARCHIVE DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  77   )
  78
  79 if(BUILD_JPIP_SERVER)
  80   add_library(openjpip_server STATIC ${OPENJPIP_SRCS} ${SERVER_SRCS})
  81   target_link_libraries(openjpip_server ${FCGI_LIBRARIES} ${CURL_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  82   set_target_properties(openjpip_server
  83     PROPERTIES COMPILE_FLAGS "-DSERVER")
  84   install(TARGETS openjpip_server
  85     EXPORT OpenJPEGTargets
  86     DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  87     )
  88 endif()