tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue418.jp2
  50     issue429.jp2
  51     issue427-null-image-size.jp2
  52     issue427-illegal-tile-offset.jp2
  53     issue495.jp2
  54     issue820.jp2
  55    )
  56
  57 # Define a list of file which should be gracefully rejected:
  58 set(BLACKLIST_JPEG2000
  59     ${BLACKLIST_JPEG2000_TMP}
  60     broken1.jp2
  61     broken2.jp2
  62     broken3.jp2
  63     broken4.jp2
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue476.jp2 #kdu_jp2info ok
  83     issue475.jp2 #kdu_jp2info ok
  84     issue413.jp2 #kdu_jp2info ok
  85    )
  86
  87 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  88      "${INPUT_NR}/*.j2k"
  89      "${INPUT_NR}/*.j2c"
  90      "${INPUT_NR}/*.jp2"
  91      "${INPUT_NR}/*.jpc"
  92      #"${INPUT_NR}/*.jpx"
  93      )
  94
  95 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  96   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  97   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  98   # cannot use longest extension function, since some name contains multiples
  99   # dots. Instead write out own shortest extension function:
 100   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 101   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 102   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 103
 104   # Dump the input image
 105   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 106            COMMAND opj_dump
 107                -i ${INPUT_FILENAME}
 108                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 109                -v
 110                )
 111
 112   if(bad_jpeg2000)
 113     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 114                          PROPERTIES WILL_FAIL TRUE)
 115
 116   else()
 117
 118     # Compare the dump output with the baseline
 119     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 120                 COMMAND compare_dump_files
 121             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 122             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 123             )
 124
 125     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 126                          PROPERTIES DEPENDS
 127                          NR-${INPUT_FILENAME_NAME}-dump)
 128   endif()
 129
 130 endforeach()
 131
 132
 133 #########################################################################
 134 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 135 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 136 # to know which files processed and with which options.
 137
 138 # Configure the test suite file:
 139 configure_file("test_suite.ctest.in"
 140                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 141                @ONLY)
 142
 143 # Read the file into a list
 144 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 145
 146 # Try to find and configure and read another test suite file
 147 file(GLOB TEST_SUITE_FILES *.ctest.in)
 148 if (TEST_SUITE_FILES)
 149   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 150
 151     # Avoid to process the official test suite
 152     set(FILE_ALREADY_READ 0)
 153     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 154     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 155
 156     if(NOT FILE_ALREADY_READ)
 157       # Configure the additional test suite file:
 158       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 159       configure_file("${TEST_SUITE_FILE}"
 160                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 161                      @ONLY)
 162       # Read the additional file into a list
 163       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 164       # Append the list of command
 165       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 166
 167     endif()
 168
 169   endforeach()
 170
 171 else()
 172
 173   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 174
 175 endif()
 176
 177
 178 set(nonregression_filenames_used)
 179 # Parse the command line found in the file(s)
 180 set(IT_TEST_ENC 0)
 181 set(IT_TEST_DEC 0)
 182 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 183
 184   set(IGNORE_LINE_FOUND 0)
 185
 186   # Replace space by ; to generate a list
 187   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 188
 189   # Check if the first argument begin by the comment sign
 190   list(GET CMD_ARG_LIST 0 EXE_NAME)
 191
 192   if(EXE_NAME)
 193     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 194   endif()
 195
 196   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 197
 198     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 199
 200   else()
 201
 202     # Check if the first argument begin by the failed sign
 203     set(FAILED_TEST_FOUND 0)
 204     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 205
 206     if (FAILED_TEST_FOUND)
 207       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 208       set(FAILED_TEST_FOUND_1 0)
 209       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 210
 211       if (FAILED_TEST_FOUND_1)
 212
 213         list(REMOVE_AT CMD_ARG_LIST 0)
 214
 215       else ()
 216
 217         set(FAILED_TEST_FOUND_2 0)
 218         list(GET CMD_ARG_LIST 1 EXE_NAME)
 219         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 220
 221         if (FAILED_TEST_FOUND_2)
 222
 223           list(REMOVE_AT CMD_ARG_LIST 0)
 224           list(REMOVE_AT CMD_ARG_LIST 0)
 225
 226         else ()
 227
 228           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 229
 230         endif ()
 231       endif ()
 232
 233     else ()
 234       # Check if the first argument is equal to opj_compress
 235       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 236
 237       if(EXE_NAME_FOUND)
 238
 239         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 240
 241       else()
 242
 243         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 244
 245       endif()
 246
 247       list(REMOVE_AT CMD_ARG_LIST 0)
 248
 249     endif ()
 250
 251     # Parse the argument list to find the input filename and output filename
 252     set(CMD_ARG_LIST_2 "")
 253     set(ARG_POS 0)
 254     set(INPUT_ARG_POS 0)
 255     set(OUTPUT_ARG_POS 0)
 256
 257     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 258
 259       math(EXPR ARG_POS "${ARG_POS}+1" )
 260
 261       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 262       if(INPUT_ARG_FOUND)
 263         set(INPUT_ARG_POS ${ARG_POS})
 264         set(INPUT_ARG_FOUND 0)
 265       endif()
 266
 267       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 268       if(OUTPUT_ARG_FOUND)
 269         set(OUTPUT_ARG_POS ${ARG_POS})
 270         set(OUTPUT_ARG_FOUND 0)
 271       endif()
 272
 273       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 274
 275     endforeach()
 276
 277     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 278     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 279     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 280     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 281     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 282
 283     #-----
 284     # Now we can add the test suite corresponding to a line command in the file
 285     #-----
 286     # ENCODER TEST SUITE
 287     if(ENC_TEST_FOUND)
 288         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 289
 290         # Encode an image into the jpeg2000 format
 291         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 292           COMMAND opj_compress
 293           ${CMD_ARG_LIST_2}
 294         )
 295
 296         if(FAILED_TEST_FOUND)
 297             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 298         else()
 299
 300           # Dump the encoding file
 301           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 302             COMMAND opj_dump
 303             -i ${OUTPUT_FILENAME}
 304             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 305           )
 306           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 307                                PROPERTIES DEPENDS
 308                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 309
 310           # Compare the dump file with the baseline
 311           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 312             COMMAND compare_dump_files
 313             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 314             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 315           )
 316
 317           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 318                                PROPERTIES DEPENDS
 319                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 320
 321           # Decode the encoding file with kakadu expand command
 322           if (KDU_EXPAND_EXECUTABLE)
 323             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 324               COMMAND ${KDU_EXPAND_EXECUTABLE}
 325               -i ${OUTPUT_FILENAME}
 326               -o ${OUTPUT_FILENAME}.raw
 327               )
 328
 329             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 330                                  PROPERTIES DEPENDS
 331                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 332
 333             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 334             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 335               COMMAND compare_raw_files
 336               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 337               -t ${OUTPUT_FILENAME}.raw
 338             )
 339
 340             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 341                                  PROPERTIES DEPENDS
 342                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 343
 344           endif()
 345
 346           # Test the encoded file is a valid JP2 file
 347           if (JPYLYZER_EXECUTABLE)
 348             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 349               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 350                 COMMAND ${JPYLYZER_EXECUTABLE}
 351                 ${OUTPUT_FILENAME}
 352                 )
 353               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 354                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 355                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 356                 )
 357             endif()
 358           endif(JPYLYZER_EXECUTABLE)
 359
 360           # If lossless compression (simple test is 4 arguments), decompress & compare
 361           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 362           if (ARG_COUNT EQUAL 4)
 363             # can we compare with the input image ?
 364             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 365               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 366                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 367                 )
 368               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 369                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 370                 )
 371               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 372                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 373                 )
 374               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 375                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 376                 )
 377             endif()
 378           endif()
 379       endif()
 380
 381     # DECODER TEST SUITE
 382     else()
 383       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 384       if(${nr_pos} GREATER 0)
 385         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 386       endif()
 387       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 388
 389       # Decode the input image
 390       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 391         COMMAND opj_decompress
 392         ${CMD_ARG_LIST_2}
 393       )
 394
 395       if(FAILED_TEST_FOUND)
 396
 397         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 398
 399       else()
 400         # if not failed, check against registered md5:
 401         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 402           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 403           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 404           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 405
 406         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 407           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 408         )
 409
 410 # FIXME: add a compare2base function base on raw which
 411 # can output png diff files if necessary
 412 #  add_test(NR-${filename}-compare2base
 413 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 414 #     -b ${BASELINE_NR}/opj_${filenameRef}
 415 #     -t ${TEMP}/${filename}.pgx
 416 #     -n ${nbComponents}
 417 #     -d
 418 #     -s b_t_
 419 #     )
 420 #
 421 #  set_tests_properties(NR-${filename}-compare2base
 422 #                       PROPERTIES DEPENDS
 423 #                       NR-${filename}-decode)
 424
 425       endif()
 426
 427     endif()
 428
 429   endif()
 430
 431 endforeach()
 432
 433 set(existing_filenames)
 434 foreach(f ${OPJ_DATA_NR_LIST})
 435   get_filename_component(ff ${f} NAME)
 436   list(APPEND existing_filenames ${ff})
 437 endforeach()
 438 if(existing_filenames)
 439 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 440 endif()
 441
 442 # keep track of new addition:
 443 # if we reach here, then a J2K files was added but no test is present in
 444 # test_suite.ctest.in:
 445 foreach(found_but_no_test ${existing_filenames})
 446   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 447   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 448 endforeach()