tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 SET(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 SET(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 SET(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9 SET(INPUT_NR_PATH ${INPUT_NR})
  10 SET(TEMP_PATH ${TEMP})
  11
  12 # need kdu_expand if possible
  13 find_package(KAKADU)
  14
  15 STRING(COMPARE EQUAL ${REF_DECODER_BIN_PATH} "NOTFOUND" REF_DECODER_NOTFOUND)
  16 IF (REF_DECODER_NOTFOUND)
  17   MESSAGE(STATUS "REF_DECODER_BIN_PATH not found, if you want all the encoding tests suite please provide a regular path")
  18 ENDIF (REF_DECODER_NOTFOUND)
  19
  20 #########################################################################
  21 # GENERATION OF THE TEST SUITE
  22 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  23 # to know which files processed and with which options.
  24
  25 # Configure the test suite file:
  26 CONFIGURE_FILE("test_suite.ctest.in"
  27                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  28                @ONLY)
  29
  30 # Read the file into a list
  31 FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  32
  33 # Try to find and configure and read another test suite file
  34 FILE(GLOB TEST_SUITE_FILES *.ctest.in)
  35 IF (TEST_SUITE_FILES)
  36   FOREACH(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  37
  38     # Avoid to process the official test suite
  39     SET(FILE_ALREADY_READ 0)
  40     STRING(REGEX MATCH "test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILE})
  41
  42     IF(NOT FILE_ALREADY_READ)
  43       # Configure the additional test suite file:
  44       GET_FILENAME_COMPONENT(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
  45       CONFIGURE_FILE("${TEST_SUITE_FILE}"
  46                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
  47                      @ONLY)
  48       # Read the additional file into a list
  49       FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
  50       # Append the list of command
  51       SET(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
  52
  53     ENDIF(NOT FILE_ALREADY_READ)
  54
  55   ENDFOREACH(TEST_SUITE_FILE)
  56
  57 ELSE(TEST_SUITE_FILES)
  58
  59   MESSAGE(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
  60
  61 ENDIF(TEST_SUITE_FILES)
  62
  63
  64 # Parse the command line found in the file(s)
  65 SET(IT_TEST_ENC 0)
  66 SET(IT_TEST_DEC 0)
  67 FOREACH(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
  68
  69   SET(IGNORE_LINE_FOUND 0)
  70
  71   # Replace space by ; to generate a list
  72   STRING(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
  73
  74   # Check if the first argument begin by the comment sign
  75   LIST(GET CMD_ARG_LIST 0 EXE_NAME)
  76   STRING(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
  77
  78   IF(IGNORE_LINE_FOUND)
  79
  80     #MESSAGE( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
  81
  82   ELSE(IGNORE_LINE_FOUND)
  83
  84     # Check if the first argument begin by the failed sign
  85     SET(FAILED_TEST_FOUND 0)
  86     STRING(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
  87
  88     IF (FAILED_TEST_FOUND)
  89       # Manage the different cases with the failed sign to remove the first argument which must be image_to_j2k
  90       SET(FAILED_TEST_FOUND_1 0)
  91       STRING(REGEX MATCH "^!image_to_j2k$|^!j2k_to_image$" FAILED_TEST_FOUND_1 ${EXE_NAME})
  92
  93       IF (FAILED_TEST_FOUND_1)
  94
  95         LIST(REMOVE_AT CMD_ARG_LIST 0)
  96
  97       ELSE (FAILED_TEST_FOUND_1)
  98
  99         SET(FAILED_TEST_FOUND_2 0)
 100         LIST(GET CMD_ARG_LIST 1 EXE_NAME)
 101         STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 102
 103         IF (FAILED_TEST_FOUND_2)
 104
 105           LIST(REMOVE_AT CMD_ARG_LIST 0)
 106           LIST(REMOVE_AT CMD_ARG_LIST 0)
 107
 108         ELSE (FAILED_TEST_FOUND_2)
 109
 110           MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k or j2k_to_image)")
 111
 112         ENDIF (FAILED_TEST_FOUND_2)
 113       ENDIF (FAILED_TEST_FOUND_1)
 114
 115     ELSE (FAILED_TEST_FOUND)
 116       # Check if the first argument is equal to image_to_j2k
 117       STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" EXE_NAME_FOUND ${EXE_NAME})
 118
 119       IF(EXE_NAME_FOUND)
 120
 121         STRING(REGEX MATCH "image_to_j2k" ENC_TEST_FOUND ${EXE_NAME})
 122
 123       ELSE(EXE_NAME_FOUND)
 124
 125         MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k)")
 126
 127       ENDIF(EXE_NAME_FOUND)
 128
 129       LIST(REMOVE_AT CMD_ARG_LIST 0)
 130
 131     ENDIF (FAILED_TEST_FOUND)
 132
 133     # Parse the argument list to find the input filename and output filename
 134     SET(CMD_ARG_LIST_2 "")
 135     SET(ARG_POS 0)
 136     SET(INPUT_ARG_POS 0)
 137     SET(OUTPUT_ARG_POS 0)
 138
 139     FOREACH(CMD_ARG_ELT ${CMD_ARG_LIST})
 140
 141       math(EXPR ARG_POS "${ARG_POS}+1" )
 142
 143       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 144       IF(INPUT_ARG_FOUND)
 145         SET(INPUT_ARG_POS ${ARG_POS})
 146         SET(INPUT_ARG_FOUND 0)
 147       ENDIF(INPUT_ARG_FOUND)
 148
 149       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 150       IF(OUTPUT_ARG_FOUND)
 151         SET(OUTPUT_ARG_POS ${ARG_POS})
 152         SET(OUTPUT_ARG_FOUND 0)
 153       ENDIF(OUTPUT_ARG_FOUND)
 154
 155       LIST (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 156
 157     ENDFOREACH(CMD_ARG_ELT)
 158
 159     LIST(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 160     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 161     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 162     LIST(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 163     GET_FILENAME_COMPONENT(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 164
 165     #-----
 166     # Now we can add the test suite corresponding to a line command in the file
 167     #-----
 168
 169     # ENCODER TEST SUITE
 170     IF(ENC_TEST_FOUND)
 171         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 172
 173         # Encode an image into the jpeg2000 format
 174         ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 175           ${EXECUTABLE_OUTPUT_PATH}/image_to_j2k
 176           ${CMD_ARG_LIST_2}
 177         )
 178
 179         IF(FAILED_TEST_FOUND)
 180             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 181         ELSE(FAILED_TEST_FOUND)
 182
 183           # Dump the encoding file
 184           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 185             ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
 186             -i ${OUTPUT_FILENAME}
 187             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 188           )
 189           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 190                                PROPERTIES DEPENDS
 191                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 192
 193           # Compare the dump file with the baseline
 194           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 195             ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
 196             -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 197             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 198           )
 199
 200           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 201                                PROPERTIES DEPENDS
 202                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 203
 204           # Decode the encoding file with kakadu expand command
 205           IF (KDU_EXPAND_EXECUTABLE)
 206             ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 207               ${KDU_EXPAND_EXECUTABLE}
 208               -i ${OUTPUT_FILENAME}
 209               -o ${OUTPUT_FILENAME}.raw
 210               )
 211
 212             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 213                                  PROPERTIES DEPENDS
 214                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 215
 216             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 217             ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 218               ${EXECUTABLE_OUTPUT_PATH}/compareRAWimages
 219               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 220               -t ${OUTPUT_FILENAME}.raw
 221             )
 222
 223             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 224                                  PROPERTIES DEPENDS
 225                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 226
 227           ENDIF()
 228       ENDIF(FAILED_TEST_FOUND)
 229
 230     # DECODER TEST SUITE
 231     ELSE(ENC_TEST_FOUND)
 232       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 233
 234       # Decode the input image
 235       ADD_TEST(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 236         ${EXECUTABLE_OUTPUT_PATH}/j2k_to_image
 237         ${CMD_ARG_LIST_2}
 238       )
 239
 240       IF(FAILED_TEST_FOUND)
 241
 242         SET_TESTS_PROPERTIES(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 243
 244       ELSE(FAILED_TEST_FOUND)
 245
 246 # FIXME: add a compare2base function base on raw which
 247 # can output png diff files if necesary
 248 #  ADD_TEST(NR-${filename}-compare2base
 249 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 250 #     -b ${BASELINE_NR}/opj_${filenameRef}
 251 #     -t ${TEMP}/${filename}.pgx
 252 #     -n ${nbComponents}
 253 #     -d
 254 #     -s b_t_
 255 #     )
 256 #
 257 #  SET_TESTS_PROPERTIES(NR-${filename}-compare2base
 258 #                       PROPERTIES DEPENDS
 259 #                       NR-${filename}-decode)
 260
 261         # Dump the input image
 262         ADD_TEST(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-dump
 263           ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
 264           -i ${INPUT_FILENAME}
 265           -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 266         )
 267
 268         # Compare the dump output with the baseline
 269         ADD_TEST(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-compare_dump2base
 270           ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
 271          -b ${BASELINE_NR}/opj_${INPUT_FILENAME_NAME_WE}.txt
 272          -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 273         )
 274
 275         SET_TESTS_PROPERTIES(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-compare_dump2base
 276                              PROPERTIES DEPENDS
 277                              NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-dump)
 278
 279
 280       ENDIF(FAILED_TEST_FOUND)
 281
 282     ENDIF(ENC_TEST_FOUND)
 283
 284   ENDIF(IGNORE_LINE_FOUND)
 285
 286 ENDFOREACH(OPJ_TEST_CMD_LINE)
 287