tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue418.jp2
  50     issue429.jp2
  51     issue427-null-image-size.jp2
  52     issue427-illegal-tile-offset.jp2
  53     issue495.jp2
  54    )
  55
  56 # Define a list of file which should be gracefully rejected:
  57 set(BLACKLIST_JPEG2000
  58     ${BLACKLIST_JPEG2000_TMP}
  59     broken1.jp2
  60     broken2.jp2
  61     broken3.jp2
  62     broken4.jp2
  63     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  64     gdal_fuzzer_check_comp_dx_dy.jp2
  65     gdal_fuzzer_check_number_of_tiles.jp2
  66     gdal_fuzzer_unchecked_numresolutions.jp2
  67     mem-b2ace68c-1381.jp2
  68     1851.pdf.SIGSEGV.ce9.948.jp2
  69     1888.pdf.asan.35.988.jp2
  70     issue362-2863.jp2 #kdu_jp2info ok
  71     issue362-2866.jp2
  72     issue362-2894.jp2
  73     issue400.jp2 #kdu_jp2info ok
  74     issue364-38.jp2
  75     issue364-903.jp2 #kdu_jp2info ok
  76     issue393.jp2 #kdu_jp2info ok
  77     issue408.jp2 #kdu_jp2info ok
  78     issue420.jp2 #kdu_jp2info ok
  79     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  80     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  81     issue476.jp2 #kdu_jp2info ok
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84    )
  85
  86 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  87      "${INPUT_NR}/*.j2k"
  88      "${INPUT_NR}/*.j2c"
  89      "${INPUT_NR}/*.jp2"
  90      "${INPUT_NR}/*.jpc"
  91      #"${INPUT_NR}/*.jpx"
  92      )
  93
  94 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  95   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  96   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  97   # cannot use longest extension function, since some name contains multiples
  98   # dots. Instead write out own shortest extension function:
  99   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 100   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 101   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 102
 103   # Dump the input image
 104   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 105            COMMAND opj_dump
 106                -i ${INPUT_FILENAME}
 107                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 108                -v
 109                )
 110
 111   if(bad_jpeg2000)
 112     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 113                          PROPERTIES WILL_FAIL TRUE)
 114
 115   else()
 116
 117     # Compare the dump output with the baseline
 118     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 119                 COMMAND compare_dump_files
 120             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 121             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 122             )
 123
 124     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 125                          PROPERTIES DEPENDS
 126                          NR-${INPUT_FILENAME_NAME}-dump)
 127   endif()
 128
 129 endforeach()
 130
 131
 132 #########################################################################
 133 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 134 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 135 # to know which files processed and with which options.
 136
 137 # Configure the test suite file:
 138 configure_file("test_suite.ctest.in"
 139                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 140                @ONLY)
 141
 142 # Read the file into a list
 143 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 144
 145 # Try to find and configure and read another test suite file
 146 file(GLOB TEST_SUITE_FILES *.ctest.in)
 147 if (TEST_SUITE_FILES)
 148   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 149
 150     # Avoid to process the official test suite
 151     set(FILE_ALREADY_READ 0)
 152     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 153     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 154
 155     if(NOT FILE_ALREADY_READ)
 156       # Configure the additional test suite file:
 157       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 158       configure_file("${TEST_SUITE_FILE}"
 159                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 160                      @ONLY)
 161       # Read the additional file into a list
 162       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 163       # Append the list of command
 164       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 165
 166     endif()
 167
 168   endforeach()
 169
 170 else()
 171
 172   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 173
 174 endif()
 175
 176
 177 set(nonregression_filenames_used)
 178 # Parse the command line found in the file(s)
 179 set(IT_TEST_ENC 0)
 180 set(IT_TEST_DEC 0)
 181 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 182
 183   set(IGNORE_LINE_FOUND 0)
 184
 185   # Replace space by ; to generate a list
 186   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 187
 188   # Check if the first argument begin by the comment sign
 189   list(GET CMD_ARG_LIST 0 EXE_NAME)
 190
 191   if(EXE_NAME)
 192     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 193   endif()
 194
 195   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 196
 197     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 198
 199   else()
 200
 201     # Check if the first argument begin by the failed sign
 202     set(FAILED_TEST_FOUND 0)
 203     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 204
 205     if (FAILED_TEST_FOUND)
 206       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 207       set(FAILED_TEST_FOUND_1 0)
 208       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 209
 210       if (FAILED_TEST_FOUND_1)
 211
 212         list(REMOVE_AT CMD_ARG_LIST 0)
 213
 214       else ()
 215
 216         set(FAILED_TEST_FOUND_2 0)
 217         list(GET CMD_ARG_LIST 1 EXE_NAME)
 218         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 219
 220         if (FAILED_TEST_FOUND_2)
 221
 222           list(REMOVE_AT CMD_ARG_LIST 0)
 223           list(REMOVE_AT CMD_ARG_LIST 0)
 224
 225         else ()
 226
 227           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 228
 229         endif ()
 230       endif ()
 231
 232     else ()
 233       # Check if the first argument is equal to opj_compress
 234       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 235
 236       if(EXE_NAME_FOUND)
 237
 238         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 239
 240       else()
 241
 242         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 243
 244       endif()
 245
 246       list(REMOVE_AT CMD_ARG_LIST 0)
 247
 248     endif ()
 249
 250     # Parse the argument list to find the input filename and output filename
 251     set(CMD_ARG_LIST_2 "")
 252     set(ARG_POS 0)
 253     set(INPUT_ARG_POS 0)
 254     set(OUTPUT_ARG_POS 0)
 255
 256     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 257
 258       math(EXPR ARG_POS "${ARG_POS}+1" )
 259
 260       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 261       if(INPUT_ARG_FOUND)
 262         set(INPUT_ARG_POS ${ARG_POS})
 263         set(INPUT_ARG_FOUND 0)
 264       endif()
 265
 266       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 267       if(OUTPUT_ARG_FOUND)
 268         set(OUTPUT_ARG_POS ${ARG_POS})
 269         set(OUTPUT_ARG_FOUND 0)
 270       endif()
 271
 272       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 273
 274     endforeach()
 275
 276     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 277     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 278     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 279     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 280     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 281
 282     #-----
 283     # Now we can add the test suite corresponding to a line command in the file
 284     #-----
 285     # ENCODER TEST SUITE
 286     if(ENC_TEST_FOUND)
 287         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 288
 289         # Encode an image into the jpeg2000 format
 290         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 291           COMMAND opj_compress
 292           ${CMD_ARG_LIST_2}
 293         )
 294
 295         if(FAILED_TEST_FOUND)
 296             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 297         else()
 298
 299           # Dump the encoding file
 300           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 301             COMMAND opj_dump
 302             -i ${OUTPUT_FILENAME}
 303             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 304           )
 305           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 306                                PROPERTIES DEPENDS
 307                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 308
 309           # Compare the dump file with the baseline
 310           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 311             COMMAND compare_dump_files
 312             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 313             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 314           )
 315
 316           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 317                                PROPERTIES DEPENDS
 318                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 319
 320           # Decode the encoding file with kakadu expand command
 321           if (KDU_EXPAND_EXECUTABLE)
 322             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 323               COMMAND ${KDU_EXPAND_EXECUTABLE}
 324               -i ${OUTPUT_FILENAME}
 325               -o ${OUTPUT_FILENAME}.raw
 326               )
 327
 328             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 329                                  PROPERTIES DEPENDS
 330                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 331
 332             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 333             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 334               COMMAND compare_raw_files
 335               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 336               -t ${OUTPUT_FILENAME}.raw
 337             )
 338
 339             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 340                                  PROPERTIES DEPENDS
 341                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 342
 343           endif()
 344
 345           # Test the encoded file is a valid JP2 file
 346           if (JPYLYZER_EXECUTABLE)
 347             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 348               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 349                 COMMAND ${JPYLYZER_EXECUTABLE}
 350                 ${OUTPUT_FILENAME}
 351                 )
 352               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 353                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 354                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 355                 )
 356             endif()
 357           endif(JPYLYZER_EXECUTABLE)
 358
 359           # If lossless compression (simple test is 4 arguments), decompress & compare
 360           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 361           if (ARG_COUNT EQUAL 4)
 362             # can we compare with the input image ?
 363             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 364               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 365                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 366                 )
 367               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 368                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 369                 )
 370               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 371                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 372                 )
 373               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 374                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 375                 )
 376             endif()
 377           endif()
 378       endif()
 379
 380     # DECODER TEST SUITE
 381     else()
 382       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 383       if(${nr_pos} GREATER 0)
 384         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 385       endif()
 386       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 387
 388       # Decode the input image
 389       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 390         COMMAND opj_decompress
 391         ${CMD_ARG_LIST_2}
 392       )
 393
 394       if(FAILED_TEST_FOUND)
 395
 396         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 397
 398       else()
 399         # if not failed, check against registered md5:
 400         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 401           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 402           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 403           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 404
 405         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 406           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 407         )
 408
 409 # FIXME: add a compare2base function base on raw which
 410 # can output png diff files if necessary
 411 #  add_test(NR-${filename}-compare2base
 412 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 413 #     -b ${BASELINE_NR}/opj_${filenameRef}
 414 #     -t ${TEMP}/${filename}.pgx
 415 #     -n ${nbComponents}
 416 #     -d
 417 #     -s b_t_
 418 #     )
 419 #
 420 #  set_tests_properties(NR-${filename}-compare2base
 421 #                       PROPERTIES DEPENDS
 422 #                       NR-${filename}-decode)
 423
 424       endif()
 425
 426     endif()
 427
 428   endif()
 429
 430 endforeach()
 431
 432 set(existing_filenames)
 433 foreach(f ${OPJ_DATA_NR_LIST})
 434   get_filename_component(ff ${f} NAME)
 435   list(APPEND existing_filenames ${ff})
 436 endforeach()
 437 if(existing_filenames)
 438 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 439 endif()
 440
 441 # keep track of new addition:
 442 # if we reach here, then a J2K files was added but no test is present in
 443 # test_suite.ctest.in:
 444 foreach(found_but_no_test ${existing_filenames})
 445   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 446   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 447 endforeach()