thirdparty/CMakeLists.txt

   1 IF(UNIX OR CYGWIN)
   2   SET(CMAKE_INCLUDE_PATH /usr/include /usr/local/include /opt/include
   3     /opt/local/include /usr/include/libpng /usr/include/libpng14
   4         /usr/include/libpng12 /usr/local/include/libpng
   5         /usr/local/include/libpng14 /usr/local/include/libpng12
   6         /opt/include/libpng /opt/include/libpng14 /opt/include/libpng12
   7         /opt/local/include/libpng /opt/local/include/libpng14)
   8   SET(CMAKE_LIBRARY_PATH /usr/lib /usr/local/lib /opt/lib /opt/local/lib)
   9 ENDIF(UNIX OR CYGWIN)
  10
  11 #------------
  12 # Try to find lib Z
  13 FIND_PACKAGE(ZLIB)
  14
  15 IF(ZLIB_FOUND)
  16
  17   SET(Z_LIBNAME ${ZLIB_LIBRARIES} PARENT_SCOPE)
  18   SET(Z_INCLUDE_DIRNAME ${ZLIB_INCLUDE_DIRS} PARENT_SCOPE)
  19   message(STATUS "Your system seems to have a Z lib available, we will use it to generate PNG lib")
  20
  21 ELSE (ZLIB_FOUND) # not found
  22
  23   IF(BUILD_THIRDPARTY)
  24     # Try to build it
  25     message(STATUS "We will build Z lib from thirdparty")
  26     ADD_SUBDIRECTORY(libz)
  27     SET(Z_LIBNAME z PARENT_SCOPE)
  28     SET(Z_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/include PARENT_SCOPE)
  29     SET(ZLIB_FOUND 1)
  30   ELSE (BUILD_THIRDPARTY)
  31     message(WARNING "Z lib not found, activate BUILD_THIRDPARTY if you want build it (necessary to build libPNG)")
  32   ENDIF(BUILD_THIRDPARTY)
  33
  34 ENDIF(ZLIB_FOUND)
  35
  36 #------------
  37 # Try to find lib PNG (which depends to zlib)
  38 IF (ZLIB_FOUND)
  39   FIND_PACKAGE(PNG)
  40
  41   IF(PNG_FOUND)
  42
  43     message(STATUS "Your system seems to have a PNG lib available, we will use it")
  44     SET(HAVE_PNG_H 1 PARENT_SCOPE)
  45     SET(HAVE_LIBPNG 1 PARENT_SCOPE)
  46     SET(PNG_LIBNAME ${PNG_LIBRARIES} PARENT_SCOPE)
  47     SET(PNG_INCLUDE_DIRNAME ${PNG_PNG_INCLUDE_DIR} PARENT_SCOPE)
  48
  49   ELSE(PNG_FOUND) # not found
  50
  51     IF(BUILD_THIRDPARTY)
  52       # Try to build it
  53       message(STATUS "We will build PNG lib from thirdparty")
  54       ADD_SUBDIRECTORY(libpng)
  55       SET(HAVE_PNG_H 1 PARENT_SCOPE)
  56       SET(HAVE_LIBPNG 1 PARENT_SCOPE)
  57       SET(PNG_LIBNAME png PARENT_SCOPE)
  58       SET(PNG_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/libpng PARENT_SCOPE)
  59     ELSE (BUILD_THIRDPARTY)
  60       SET(HAVE_PNG_H 0 PARENT_SCOPE)
  61       SET(HAVE_LIBPNG 0 PARENT_SCOPE)
  62       message(WARNING "PNG lib not found, activate BUILD_THIRDPARTY if you want build it")
  63     ENDIF(BUILD_THIRDPARTY)
  64
  65   ENDIF(PNG_FOUND)
  66 ENDIF (ZLIB_FOUND)
  67
  68 #------------
  69 # Try to find lib TIFF
  70 FIND_PACKAGE(TIFF)
  71
  72 IF(TIFF_FOUND)
  73
  74   message(STATUS "Your system seems to have a TIFF lib available, we will use it")
  75   SET(HAVE_TIFF_H 1 PARENT_SCOPE)
  76   SET(HAVE_LIBTIFF 1 PARENT_SCOPE)
  77   SET(TIFF_LIBNAME ${TIFF_LIBRARIES} PARENT_SCOPE)
  78   SET(TIFF_INCLUDE_DIRNAME ${TIFF_INCLUDE_DIR} PARENT_SCOPE)
  79
  80 ELSE (TIFF_FOUND) # not found
  81
  82   IF(BUILD_THIRDPARTY)
  83     # Try to build it
  84     message(STATUS "We will build TIFF lib from thirdparty")
  85     ADD_SUBDIRECTORY(libtiff)
  86     SET(TIFF_LIBNAME tiff PARENT_SCOPE)
  87     SET(TIFF_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/libtiff PARENT_SCOPE)
  88     SET(HAVE_TIFF_H 1 PARENT_SCOPE)
  89     SET(HAVE_LIBTIFF 1 PARENT_SCOPE)
  90   ELSE (BUILD_THIRDPARTY)
  91     SET(HAVE_TIFF_H 0 PARENT_SCOPE)
  92     SET(HAVE_LIBTIFF 0 PARENT_SCOPE)
  93     message(WARNING "TIFF lib not found, activate BUILD_THIRDPARTY if you want build it")
  94   ENDIF(BUILD_THIRDPARTY)
  95
  96 ENDIF(TIFF_FOUND)
  97
  98 #------------
  99 # Try to find lib LCMS2 (or by default LCMS)
 100 FIND_PACKAGE(LCMS2)
 101
 102 IF(LCMS2_FOUND)
 103
 104   message(STATUS "Your system seems to have a LCMS2 lib available, we will use it")
 105   SET(HAVE_LCMS2_H 1 PARENT_SCOPE)
 106   SET(HAVE_LIBLCMS2 1 PARENT_SCOPE)
 107   SET(LCMS_LIBNAME ${LCMS2_LIBRARIES} PARENT_SCOPE)
 108   SET(LCMS_INCLUDE_DIRNAME ${LCMS2_INCLUDE_DIRS} PARENT_SCOPE)
 109
 110 ELSE (LCMS2_FOUND) # not found lcms2
 111   # try to find LCMS
 112   FIND_PACKAGE(LCMS)
 113
 114   IF(LCMS_FOUND)
 115
 116     message(STATUS "Your system seems to have a LCMS lib available, we will use it")
 117     SET(HAVE_LCMS_H 1 PARENT_SCOPE)
 118     SET(HAVE_LIBLCMS 1 PARENT_SCOPE)
 119     SET(LCMS_LIBNAME ${LCMS_LIBRARIES} PARENT_SCOPE)
 120     SET(LCMS_INCLUDE_DIRNAME ${LCMS_INCLUDE_DIRS} PARENT_SCOPE)
 121
 122   ELSE (LCMS_FOUND) # not found lcms
 123     SET(HAVE_LCMS_H 0 PARENT_SCOPE)
 124     SET(HAVE_LIBLCMS 0 PARENT_SCOPE)
 125
 126     IF( BUILD_THIRDPARTY)
 127
 128       # Try to build lcms2
 129       message(STATUS "We will build LCMS2 lib from thirdparty")
 130       ADD_SUBDIRECTORY(liblcms2)
 131       SET(LCMS_LIBNAME lcms2 PARENT_SCOPE)
 132       SET(LCMS_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/liblcms2/include PARENT_SCOPE) #
 133       SET(HAVE_LCMS2_H 1 PARENT_SCOPE)
 134       SET(HAVE_LIBLCMS2 1 PARENT_SCOPE)
 135     ELSE (BUILD_THIRDPARTY)
 136         SET(HAVE_LCMS2_H 0 PARENT_SCOPE)
 137         SET(HAVE_LIBLCMS2 0 PARENT_SCOPE)
 138         message(WARNING "LCMS2 or LCMS lib not found, activate BUILD_THIRDPARTY if you want build it")
 139     ENDIF(BUILD_THIRDPARTY)
 140
 141   ENDIF (LCMS_FOUND)
 142 ENDIF(LCMS2_FOUND)
 143
 144 #------------
 145 # Try to find lib FCGI
 146 FIND_PACKAGE(FCGI)
 147
 148 IF(FCGI_FOUND)
 149
 150   SET(FCGI_LIBNAME ${FCGI_LIBRARIES} PARENT_SCOPE)
 151   SET(FCGI_INCLUDE_DIRNAME ${FCGI_INCLUDE_DIRS} PARENT_SCOPE)
 152   message(STATUS "Your system seems to have a FCGI lib available, we will use it to build JPIP")
 153
 154 ELSE (FCGI_FOUND) # not found
 155
 156   message(WARNING "FCGI lib not found, JPIP will not be built as it requires FCGI")
 157
 158 ENDIF(FCGI_FOUND)
 159
 160
 161