thirdparty/libtiff/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 project(libtiff C)
   3 # This convenient copy of libtiff does not support encapsulated zlib or jpeg
   4 # stream. see ZIP_SUPPORT and JPEG_SUPPORT values
   5
   6 INCLUDE_DIRECTORIES(BEFORE "${CMAKE_CURRENT_SOURCE_DIR}")
   7 INCLUDE_DIRECTORIES(BEFORE "${CMAKE_CURRENT_BINARY_DIR}")
   8
   9 SET(TARGET_FILES
  10   t4.h
  11   tiffiop.h
  12   tif_aux.c
  13   tif_close.c
  14   tif_codec.c
  15   tif_color.c
  16   tif_compress.c
  17   tif_dir.c
  18   tif_dir.h
  19   tif_dirinfo.c
  20   tif_dirread.c
  21   tif_dirwrite.c
  22   tif_dumpmode.c
  23   tif_error.c
  24   tif_extension.c
  25   tif_fax3.c
  26   tif_fax3.h
  27   tif_fax3sm.c
  28   tif_flush.c
  29   tif_getimage.c
  30   tif_jbig.c
  31   tif_jpeg.c
  32   tif_luv.c
  33   tif_lzw.c
  34   tif_next.c
  35   tif_ojpeg.c
  36   tif_open.c
  37   tif_packbits.c
  38   tif_pixarlog.c
  39   tif_predict.c
  40   tif_predict.h
  41   tif_print.c
  42   tif_read.c
  43   tif_strip.c
  44   tif_swab.c
  45   tif_thunder.c
  46   tif_tile.c
  47   tif_version.c
  48   tif_warning.c
  49   tif_write.c
  50   tif_zip.c
  51   tif_jpeg_12.c
  52   tif_lzma.c
  53   uvcode.h
  54   )
  55
  56 IF(UNIX)
  57   SET(TARGET_FILES ${TARGET_FILES} tif_unix.c)
  58 ELSE()
  59   SET(TARGET_FILES ${TARGET_FILES} tif_win32.c)
  60 ENDIF()
  61
  62 include(${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
  63 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  64 set(HOST_BIGENDIAN ${WORDS_BIGENDIAN})
  65 if(HOST_BIGENDIAN)
  66 set(HOST_FILLORDER "FILLORDER_MSB2LSB")
  67 else()
  68 set(HOST_FILLORDER "FILLORDER_LSB2MSB")
  69 endif()
  70 include(CheckIncludeFiles)
  71 include(CheckSymbolExists)
  72 include(CheckFunctionExists)
  73
  74 CHECK_INCLUDE_FILES("zlib.h" HAVE_ZLIB_H)
  75 CHECK_INCLUDE_FILES("jpeglib.h" HAVE_JPEGLIB_H)
  76 if(HAVE_JPEGLIB_H)
  77   set(JPEG_SUPPORT 1)
  78 endif()
  79 if(HAVE_ZLIB_H)
  80   set(ZIP_SUPPORT 1)
  81   set(PIXARLOG_SUPPORT 1) # require zlib
  82 endif()
  83 CHECK_INCLUDE_FILES("assert.h" HAVE_ASSERT_H)
  84 CHECK_INCLUDE_FILES("dlfcn.h" HAVE_DLFCN_H)
  85 CHECK_INCLUDE_FILES("fcntl.h" HAVE_FCNTL_H)
  86 CHECK_INCLUDE_FILES("inttypes.h" HAVE_INTTYPES_H)
  87 CHECK_INCLUDE_FILES("io.h" HAVE_IO_H)
  88 CHECK_INCLUDE_FILES("limits.h" HAVE_LIMITS_H)
  89 CHECK_INCLUDE_FILES("malloc.h" HAVE_MALLOC_H)
  90 CHECK_INCLUDE_FILES("memory.h" HAVE_MEMORY_H)
  91 CHECK_INCLUDE_FILES("search.h" HAVE_SEARCH_H)
  92 CHECK_INCLUDE_FILES("stdint.h" HAVE_STDINT_H)
  93 CHECK_INCLUDE_FILES("stdlib.h" HAVE_STDLIB_H)
  94 CHECK_INCLUDE_FILES("string.h" HAVE_STRING_H)
  95 CHECK_INCLUDE_FILES("strings.h" HAVE_STRINGS_H)
  96 CHECK_INCLUDE_FILES("sys/stat.h" HAVE_SYS_STAT_H)
  97 CHECK_INCLUDE_FILES("sys/time.h" HAVE_SYS_TIME_H)
  98 CHECK_INCLUDE_FILES("time.h" HAVE_TIME_H)
  99 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 100 CHECK_INCLUDE_FILES("unistd.h" HAVE_UNISTD_H)
 101 CHECK_INCLUDE_FILES("windows.h" HAVE_WINDOWS_H)
 102 CHECK_INCLUDE_FILES("strings.h" HAVE_STRINGS_H)
 103 CHECK_INCLUDE_FILES("ieeefp.h" HAVE_IEEEFP_H)
 104
 105 # wotsit ?
 106 if( HAVE_TIME_H AND HAVE_SYS_TIME_H )
 107  set(TIME_WITH_SYS_TIME 1)
 108 endif()
 109 set(LZMA_SUPPORT 0) # ?
 110 set(MDI_SUPPORT 1) # ?
 111 set(STDC_HEADERS 1) # why not ?
 112 set(DEFAULT_EXTRASAMPLE_AS_ALPHA 1)
 113 set(CHECK_JPEG_YCBCR_SUBSAMPLING 1)
 114 set(CCITT_SUPPORT 1)
 115 set(DEFER_STRILE_LOAD 0)
 116 set(HAVE_JBG_NEWLEN 0) # FIXME: jbigkit stuff
 117 set(STRIPCHOP_DEFAULT "TIFF_STRIPCHOP")
 118 set(STRIP_SIZE_DEFAULT 8192)
 119 set(SUBIFD_SUPPORT 1)
 120 set(THUNDER_SUPPORT 1)
 121
 122 CHECK_FUNCTION_EXISTS(getopt HAVE_GETOPT)
 123 CHECK_FUNCTION_EXISTS(isascii HAVE_ISASCII)
 124 CHECK_FUNCTION_EXISTS(memmove HAVE_MEMMOVE)
 125 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 126 CHECK_FUNCTION_EXISTS(mmap HAVE_MMAP)
 127 CHECK_FUNCTION_EXISTS(strcasecmp HAVE_STRCASECMP)
 128 CHECK_FUNCTION_EXISTS(strchr HAVE_STRCHR)
 129 CHECK_FUNCTION_EXISTS(strrchr HAVE_STRRCHR)
 130 CHECK_FUNCTION_EXISTS(strstr HAVE_STRSTR)
 131 CHECK_FUNCTION_EXISTS(strtol HAVE_STRTOL)
 132 CHECK_FUNCTION_EXISTS(strtoul HAVE_STRTOUL)
 133 CHECK_FUNCTION_EXISTS(strtoull HAVE_STRTOULL)
 134
 135 include(CheckTypeSize)
 136
 137 CHECK_TYPE_SIZE("signed int"         SIZEOF_SIGNED_INT)
 138 CHECK_TYPE_SIZE("signed long"        SIZEOF_SIGNED_LONG)
 139 CHECK_TYPE_SIZE("signed long long"   SIZEOF_SIGNED_LONG_LONG)
 140 CHECK_TYPE_SIZE("signed short"       SIZEOF_SIGNED_SHORT)
 141 CHECK_TYPE_SIZE("unsigned int"       SIZEOF_UNSIGNED_INT)
 142 CHECK_TYPE_SIZE("unsigned long"      SIZEOF_UNSIGNED_LONG)
 143 CHECK_TYPE_SIZE("unsigned long long" SIZEOF_UNSIGNED_LONG_LONG)
 144 CHECK_TYPE_SIZE("unsigned short"     SIZEOF_UNSIGNED_SHORT)
 145 CHECK_TYPE_SIZE("unsigned char*"     SIZEOF_UNSIGNED_CHAR_P)
 146 # check platform has ssize_t:
 147 CHECK_TYPE_SIZE(ssize_t     SSIZE_T)
 148
 149 if(HAVE_STDINT_H)
 150   set(TIFF_INT8_T    int8_t)
 151   set(TIFF_INT16_T   int16_t)
 152   set(TIFF_INT32_T   int32_t)
 153   set(TIFF_INT64_T   int64_t)
 154   set(TIFF_UINT8_T   uint8_t)
 155   set(TIFF_UINT16_T  uint16_t)
 156   set(TIFF_UINT32_T  uint32_t)
 157   set(TIFF_UINT64_T  uint64_t)
 158   set(TIFF_PTRDIFF_T ptrdiff_t)
 159   if(NOT HAVE_SSIZE_T)
 160     if("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 161       set(TIFF_SSIZE_T   int64_t)
 162     elseif("${CMAKE_SIZEOF_VOID_P}" EQUAL 4)
 163       set(TIFF_SSIZE_T   int32_t)
 164     else()
 165       message(FATAL_ERROR "unknown ssize_t")
 166     endif()
 167   else()
 168     set(TIFF_SSIZE_T   ssize_t)
 169   endif()
 170   set(TIFF_INT32_FORMAT "\"%d\"")
 171   set(TIFF_UINT32_FORMAT "\"%u\"")
 172   set(TIFF_INT64_FORMAT "\"%ld\"")
 173   set(TIFF_UINT64_FORMAT "\"%lu\"")
 174   set(TIFF_PTRDIFF_FORMAT "\"%ld\"")
 175   set(TIFF_SSIZE_FORMAT "\"%ld\"")
 176 endif()
 177
 178 #
 179 set(VERSION "\"4.0.1\"")
 180 set(PACKAGE_VERSION ${VERSION})
 181 set(PACKAGE "\"tiff\"")
 182
 183 if(UNIX)
 184   set(CMAKE_REQUIRED_LIBRARIES m)
 185   set(HAVE_LIBM 1)
 186 endif()
 187 CHECK_SYMBOL_EXISTS(floor "math.h" HAVE_FLOOR)
 188 CHECK_SYMBOL_EXISTS(sqrt "math.h" HAVE_SQRT)
 189 CHECK_SYMBOL_EXISTS(pow "math.h" HAVE_POW)
 190 CHECK_SYMBOL_EXISTS(lfind "search.h" HAVE_LFIND)
 191 CHECK_SYMBOL_EXISTS(setmod "io.h" HAVE_SETMODE)
 192
 193 # http://www.cmake.org/pipermail/cmake/2007-September/016285.html
 194 FOREACH(KEYWORD "inline" "__inline__" "__inline")
 195   IF(NOT DEFINED C_INLINE)
 196     TRY_COMPILE(C_HAS_${KEYWORD} "${CMAKE_CURRENT_BINARY_DIR}"
 197        "${CMAKE_CURRENT_SOURCE_DIR}/test_inline.c"
 198        COMPILE_DEFINITIONS "-Dinline=${KEYWORD}")
 199     IF(C_HAS_${KEYWORD})
 200       SET(C_INLINE TRUE)
 201       SET(INLINE "${KEYWORD}")
 202     ENDIF(C_HAS_${KEYWORD})
 203   ENDIF(NOT DEFINED C_INLINE)
 204 ENDFOREACH(KEYWORD)
 205
 206 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/tiffconf.h.cmake.in
 207   ${CMAKE_CURRENT_BINARY_DIR}/tiffconf.h @ONLY)
 208 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/tif_config.h.cmake.in
 209   ${CMAKE_CURRENT_BINARY_DIR}/tif_config.h @ONLY)
 210
 211 SET(LIBTARGET "tiff")
 212 #
 213 ADD_LIBRARY(${LIBTARGET} STATIC ${TARGET_FILES})
 214 #
 215 SET_TARGET_PROPERTIES(${LIBTARGET}
 216   PROPERTIES
 217   OUTPUT_NAME "${LIBTARGET}"
 218   ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/thirdparty/lib
 219 )