tools/ctest_scripts/travis-ci.cmake

   1 # -----------------------------------------------------------------------------
   2 # Travis-ci ctest script for OpenJPEG project
   3 # This will compile/run tests/upload to cdash OpenJPEG
   4 # Results will be available at: http://my.cdash.org/index.php?project=OPENJPEG
   5 # -----------------------------------------------------------------------------
   6
   7 cmake_minimum_required(VERSION 2.8)
   8
   9 set( ENV{LANG} en_US.UTF-8)
  10 set( CTEST_DASHBOARD_ROOT  "$ENV{PWD}/build" )
  11 set( CTEST_CMAKE_GENERATOR "Unix Makefiles")   # Always makefile in travis-ci environment
  12
  13 if ("$ENV{OPJ_BUILD_CONFIGURATION}" STREQUAL "")
  14   set( CTEST_BUILD_CONFIGURATION "Release")
  15 else()
  16         set( CTEST_BUILD_CONFIGURATION "$ENV{OPJ_BUILD_CONFIGURATION}")
  17 endif()
  18
  19 if ("$ENV{OPJ_SITE}" STREQUAL "")
  20   set( CTEST_SITE "Unknown")
  21 else()
  22         set( CTEST_SITE "$ENV{OPJ_SITE}")
  23 endif()
  24
  25 if ("$ENV{OPJ_BUILDNAME}" STREQUAL "")
  26   set( CTEST_BUILD_NAME "Unknown-${CTEST_BUILD_CONFIGURATION}")
  27 else()
  28         set( CTEST_BUILD_NAME "$ENV{OPJ_BUILDNAME}")
  29 endif()
  30
  31 # To execute part of the encoding test suite, kakadu binaries are needed to decode encoded image and compare
  32 # it to the baseline. Kakadu binaries are freely available for non-commercial purposes
  33 # at http://www.kakadusoftware.com.
  34 # Here's the copyright notice from kakadu:
  35 # Copyright is owned by NewSouth Innovations Pty Limited, commercial arm of the UNSW Australia in Sydney.
  36 # You are free to trial these executables and even to re-distribute them,
  37 # so long as such use or re-distribution is accompanied with this copyright notice and is not for commercial gain.
  38 # Note: Binaries can only be used for non-commercial purposes.
  39 if ("$ENV{OPJ_NONCOMMERCIAL}" STREQUAL "1")
  40         set(KDUPATH $ENV{PWD}/kdu)
  41         set(ENV{LD_LIBRARY_PATH} ${KDUPATH})
  42         set(ENV{PATH} $ENV{PATH}:${KDUPATH})
  43 endif()
  44
  45 # Options
  46 set( CACHE_CONTENTS "
  47
  48 # Build kind
  49 CMAKE_BUILD_TYPE:STRING=${CTEST_BUILD_CONFIGURATION}
  50
  51 # Warning level
  52 CMAKE_C_FLAGS:STRING= -Wall -Wextra -Wconversion -Wpedantic -Wno-unused-parameter -Wdeclaration-after-statement
  53
  54 # Use to activate the test suite
  55 BUILD_TESTING:BOOL=TRUE
  56
  57 # Build Thirdparty, useful but not required for test suite
  58 BUILD_THIRDPARTY:BOOL=TRUE
  59
  60 # JPEG2000 test files are available with git clone https://github.com/uclouvain/openjpeg-data.git
  61 OPJ_DATA_ROOT:PATH=$ENV{PWD}/data
  62
  63 # jpylyzer is available with on GitHub: https://github.com/openpreserve/jpylyzer
  64 JPYLYZER_EXECUTABLE=$ENV{PWD}/jpylyzer/jpylyzer/jpylyzer.py
  65
  66 " )
  67
  68 #---------------------
  69 #1. openjpeg specific:
  70 set( CTEST_PROJECT_NAME "OPENJPEG" )
  71 if(NOT EXISTS $ENV{OPJ_SOURCE_DIR})
  72         message(FATAL_ERROR "OPJ_SOURCE_DIR not defined or does not exist:$ENV{OPJ_SOURCE_DIR}")
  73 endif()
  74 set( CTEST_SOURCE_DIRECTORY     "$ENV{OPJ_SOURCE_DIR}")
  75 set( CTEST_BINARY_DIRECTORY     "${CTEST_DASHBOARD_ROOT}")
  76
  77 #---------------------
  78 # Files to submit to the dashboard
  79 set (CTEST_NOTES_FILES
  80 ${CTEST_SCRIPT_DIRECTORY}/${CTEST_SCRIPT_NAME}
  81 ${CTEST_BINARY_DIRECTORY}/CMakeCache.txt )
  82
  83 ctest_empty_binary_directory( "${CTEST_BINARY_DIRECTORY}" )
  84 file(WRITE "${CTEST_BINARY_DIRECTORY}/CMakeCache.txt" "${CACHE_CONTENTS}")
  85
  86 # Perform a Experimental build
  87 ctest_start(Experimental)
  88 #ctest_update(SOURCE "${CTEST_SOURCE_DIRECTORY}")
  89 ctest_configure(BUILD "${CTEST_BINARY_DIRECTORY}")
  90 ctest_read_custom_files(${CTEST_BINARY_DIRECTORY})
  91 ctest_build(BUILD "${CTEST_BINARY_DIRECTORY}")
  92 ctest_test(BUILD "${CTEST_BINARY_DIRECTORY}" PARALLEL_LEVEL 2)
  93
  94 if ("$ENV{OPJ_DO_SUBMIT}" STREQUAL "1")
  95         ctest_submit()
  96 endif()
  97 ctest_empty_binary_directory( "${CTEST_BINARY_DIRECTORY}" )