CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # set(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 cmake_minimum_required(VERSION 2.8.2)
  11
  12 if(COMMAND CMAKE_POLICY)
  13   cmake_policy(SET CMP0003 NEW)
  14 endif()
  15
  16 if(NOT OPENJPEG_NAMESPACE)
  17   set(OPENJPEG_NAMESPACE "OPENJPEG")
  18   set(OPENJPEG_STANDALONE 1)
  19 endif()
  20 # In all cases:
  21 #string(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22 set(OPENJPEG_LIBRARY_NAME openjp2)
  23
  24 project(${OPENJPEG_NAMESPACE} C)
  25
  26 # Do full dependency headers.
  27 include_regular_expression("^.*$")
  28
  29 #-----------------------------------------------------------------------------
  30 # OPENJPEG version number, useful for packaging and doxygen doc:
  31 set(OPENJPEG_VERSION_MAJOR 2)
  32 set(OPENJPEG_VERSION_MINOR 1)
  33 set(OPENJPEG_VERSION_BUILD 0)
  34 set(OPENJPEG_VERSION
  35   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  36 set(PACKAGE_VERSION
  37   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  38
  39 # Because autotools does not support X.Y notation for SOVERSION, we have to use
  40 # two numbering, one for the openjpeg version and one for openjpeg soversion
  41 # version | soversion
  42 #   1.0   |  0
  43 #   1.1   |  1
  44 #   1.2   |  2
  45 #   1.3   |  3
  46 #   1.4   |  4
  47 #   1.5   |  5
  48 #   1.5.1 |  5
  49 #   2.0   |  6
  50 #   2.0.1 |  6
  51 #   2.1   |  7
  52 # above is the recommendation by the OPJ team. If you really need to override this default,
  53 # you can specify your own OPENJPEG_SOVERSION at cmake configuration time:
  54 # cmake -DOPENJPEG_SOVERSION:STRING=42 /path/to/openjpeg
  55 if(NOT OPENJPEG_SOVERSION)
  56   SET(OPENJPEG_SOVERSION 7)
  57 endif(NOT OPENJPEG_SOVERSION)
  58 set(OPENJPEG_LIBRARY_PROPERTIES
  59   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  60   SOVERSION "${OPENJPEG_SOVERSION}"
  61 )
  62
  63 # --------------------------------------------------------------------------
  64 # Path to additional CMake modules
  65 set(CMAKE_MODULE_PATH
  66     ${CMAKE_SOURCE_DIR}/cmake
  67     ${CMAKE_MODULE_PATH})
  68
  69 # --------------------------------------------------------------------------
  70 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  71 # warnings
  72 if(WIN32)
  73   if(NOT BORLAND)
  74     if(NOT CYGWIN)
  75       if(NOT MINGW)
  76         if(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  77           add_definitions(
  78             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  79             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  80             -D_CRT_MANAGED_FP_NO_DEPRECATE
  81             -D_CRT_NONSTDC_NO_DEPRECATE
  82             -D_CRT_SECURE_NO_DEPRECATE
  83             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  84             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  85             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  86             -D_CRT_VCCLRIT_NO_DEPRECATE
  87             -D_SCL_SECURE_NO_DEPRECATE
  88             )
  89         endif()
  90       endif()
  91     endif()
  92   endif()
  93 endif()
  94
  95
  96 # --------------------------------------------------------------------------
  97 # Install directories
  98 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
  99 option(BUILD_DOC "Build the HTML documentation (with doxygen if available)." OFF)
 100
 101 string(TOLOWER ${PROJECT_NAME} projectname)
 102 set(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
 103
 104 if(NOT OPENJPEG_INSTALL_BIN_DIR)
 105   set(OPENJPEG_INSTALL_BIN_DIR "bin")
 106 endif()
 107
 108 if(NOT OPENJPEG_INSTALL_LIB_DIR)
 109   set(OPENJPEG_INSTALL_LIB_DIR "lib")
 110 endif()
 111
 112 if(NOT OPENJPEG_INSTALL_SHARE_DIR)
 113   set(OPENJPEG_INSTALL_SHARE_DIR "share")
 114 endif()
 115
 116 if(NOT OPENJPEG_INSTALL_DATA_DIR)
 117   set(OPENJPEG_INSTALL_DATA_DIR "${OPENJPEG_INSTALL_SHARE_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 118 endif()
 119
 120 if(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
 121   set(OPENJPEG_INSTALL_INCLUDE_DIR "include/${OPENJPEG_INSTALL_SUBDIR}")
 122 endif()
 123
 124 if(BUILD_DOC)
 125 if(NOT OPENJPEG_INSTALL_MAN_DIR)
 126   set(OPENJPEG_INSTALL_MAN_DIR "share/man/")
 127 endif()
 128
 129 if(NOT OPENJPEG_INSTALL_DOC_DIR)
 130   set(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 131 endif()
 132 endif()
 133
 134 if(NOT OPENJPEG_INSTALL_JNI_DIR)
 135   if(WIN32)
 136     set(OPENJPEG_INSTALL_JNI_DIR ${OPENJPEG_INSTALL_BIN_DIR})
 137   else()
 138     set(OPENJPEG_INSTALL_JNI_DIR ${OPENJPEG_INSTALL_LIB_DIR})
 139   endif()
 140 endif()
 141
 142 if(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 143   # We could install *.cmake files in share/ however those files contains
 144   # hardcoded path to libraries on a multi-arch system (fedora/debian) those
 145   # path will be different (lib/i386-linux-gnu vs lib/x86_64-linux-gnu)
 146   set(OPENJPEG_INSTALL_PACKAGE_DIR "${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 147 endif()
 148
 149 #-----------------------------------------------------------------------------
 150 # Big endian test:
 151 include (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 152 TEST_BIG_ENDIAN(OPJ_BIG_ENDIAN)
 153
 154 #-----------------------------------------------------------------------------
 155 # Setup file for setting custom ctest vars
 156 configure_file(
 157   ${CMAKE_SOURCE_DIR}/cmake/CTestCustom.cmake.in
 158   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 159   @ONLY
 160   )
 161
 162 #-----------------------------------------------------------------------------
 163 # OpenJPEG build configuration options.
 164 option(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 165 set (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 166 set (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 167 mark_as_advanced(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 168
 169 #-----------------------------------------------------------------------------
 170 # configure name mangling to allow multiple libraries to coexist
 171 # peacefully
 172 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 173 set(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 174 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 175                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 176                @ONLY)
 177 endif()
 178
 179 #-----------------------------------------------------------------------------
 180 # Compiler specific flags:
 181 if(CMAKE_COMPILER_IS_GNUCC)
 182   # For all builds, make sure openjpeg is std99 compliant:
 183   # set(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 184   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 185   set(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 186 endif()
 187
 188 #-----------------------------------------------------------------------------
 189 # opj_config.h generation (1/2)
 190
 191 # Check if some include files are provided by the system
 192 include(EnsureFileInclude)
 193 # These files are mandatory
 194 ensure_file_include("string.h"   HAVE_STRING_H YES)
 195 ensure_file_include("memory.h"   HAVE_MEMORY_H YES)
 196 ensure_file_include("stdlib.h"   HAVE_STDLIB_H YES)
 197 ensure_file_include("stdio.h"    HAVE_STDIO_H  YES)
 198 ensure_file_include("math.h"     HAVE_MATH_H   YES)
 199 ensure_file_include("float.h"    HAVE_FLOAT_H  YES)
 200 ensure_file_include("time.h"     HAVE_TIME_H   YES)
 201 ensure_file_include("stdarg.h"   HAVE_STDARG_H YES)
 202 ensure_file_include("ctype.h"    HAVE_CTYPE_H  YES)
 203 ensure_file_include("assert.h"   HAVE_ASSERT_H YES)
 204
 205 # For the following files, we provide an alternative, they are not mandatory
 206 ensure_file_include("stdint.h"   OPJ_HAVE_STDINT_H   NO)
 207 ensure_file_include("inttypes.h" OPJ_HAVE_INTTYPES_H NO)
 208
 209 # why check this one ? for openjpip ?
 210 include (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 211 CHECK_INCLUDE_FILE("strings.h"      HAVE_STRINGS_H)
 212 CHECK_INCLUDE_FILE("sys/stat.h"     HAVE_SYS_STAT_H)
 213 CHECK_INCLUDE_FILE("sys/types.h"    HAVE_SYS_TYPES_H)
 214 CHECK_INCLUDE_FILE("unistd.h"       HAVE_UNISTD_H)
 215
 216 # Enable Large file support
 217 include(TestLargeFiles)
 218 OPJ_TEST_LARGE_FILES(OPJ_HAVE_LARGEFILES)
 219
 220 #-----------------------------------------------------------------------------
 221 # Build Library
 222 if(BUILD_JPIP_SERVER)
 223   find_package(CURL REQUIRED)
 224   find_package(FCGI REQUIRED)
 225   find_package(Threads REQUIRED)
 226   if(NOT CMAKE_USE_PTHREADS_INIT)
 227     message(FATAL_ERROR "Only pthread are supported")
 228   endif()
 229 endif()
 230 add_subdirectory(src/lib)
 231
 232 #-----------------------------------------------------------------------------
 233 # Build Applications
 234 option(BUILD_CODEC "Build the CODEC executables" ON)
 235 option(BUILD_MJ2 "Build the MJ2 executables." OFF)
 236 option(BUILD_JPWL "Build the JPWL library and executables" OFF)
 237 option(BUILD_JPIP "Build the JPIP library and executables." OFF)
 238 if(BUILD_JPIP)
 239   option(BUILD_JPIP_SERVER "Build the JPIP server." OFF)
 240 endif()
 241 option(BUILD_VIEWER "Build the OPJViewer executable (C++)" OFF)
 242 option(BUILD_JAVA "Build the openjpeg jar (Java)" OFF)
 243 option(BUILD_JP3D "Build the JP3D comp" OFF)
 244 mark_as_advanced(BUILD_VIEWER)
 245 mark_as_advanced(BUILD_JAVA)
 246 mark_as_advanced(BUILD_JP3D)
 247
 248 if(BUILD_CODEC OR BUILD_MJ2)
 249   # OFF: It will only build 3rd party libs if they are not found on the system
 250   # ON: 3rd party libs will ALWAYS be build, and used
 251   option(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 252   add_subdirectory(thirdparty)
 253   add_subdirectory(src/bin)
 254 endif ()
 255 add_subdirectory(wrapping)
 256
 257 #-----------------------------------------------------------------------------
 258 # opj_config.h generation (2/2)
 259 configure_file(
 260  ${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/opj_config.h.cmake.in
 261  ${CMAKE_CURRENT_BINARY_DIR}/src/lib/openjp2/opj_config.h
 262  @ONLY
 263  )
 264
 265  configure_file(
 266  ${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/opj_config_private.h.cmake.in
 267  ${CMAKE_CURRENT_BINARY_DIR}/src/lib/openjp2/opj_config_private.h
 268  @ONLY
 269  )
 270
 271 #-----------------------------------------------------------------------------
 272 # build documentation in doc subdir:
 273 if(BUILD_DOC)
 274   add_subdirectory(doc)
 275 endif()
 276
 277 #-----------------------------------------------------------------------------
 278 # Buld Testing
 279 option(BUILD_TESTING "Build the tests." OFF)
 280 if(BUILD_TESTING)
 281   if(BUILD_CODEC)
 282     enable_testing()
 283     include(CTest)
 284
 285     # Search openjpeg data needed for the tests
 286     # They could be found via svn on the OpenJPEG google code project
 287     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 288     find_path(OPJ_DATA_ROOT README-OPJ-Data
 289       PATHS $ENV{OPJ_DATA_ROOT} ${CMAKE_SOURCE_DIR}/../data
 290       NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH
 291       )
 292
 293     # Add repository where to find tests
 294     add_subdirectory(tests)
 295
 296   else()
 297     message(FATAL_ERROR "You need build codec to run the tests")
 298   endif()
 299 endif()
 300
 301 #-----------------------------------------------------------------------------
 302 # install all targets referenced as OPENJPEGTargets
 303 install(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 304 configure_file( ${OPENJPEG_SOURCE_DIR}/cmake/OpenJPEGConfig.cmake.in
 305   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 306   @ONLY
 307 )
 308 install( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 309   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 310 )
 311
 312 #-----------------------------------------------------------------------------
 313 # install CHANGES and LICENSE
 314 if(BUILD_DOC)
 315 if(EXISTS ${OPENJPEG_SOURCE_DIR}/CHANGES)
 316   install(FILES CHANGES DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 317 endif()
 318
 319 install(FILES LICENSE DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 320 endif()
 321
 322 include (cmake/OpenJPEGCPack.cmake)
 323
 324 #-----------------------------------------------------------------------------
 325 # pkgconfig support
 326 # enabled by default on Unix, disabled by default on other platforms
 327 if(UNIX)
 328   option(BUILD_PKGCONFIG_FILES "Build and install pkg-config files" ON)
 329 else()
 330   option(BUILD_PKGCONFIG_FILES "Build and install pkg-config files" OFF)
 331 endif()
 332 if(BUILD_PKGCONFIG_FILES)
 333   # install in lib and not share (see multi-arch note above)
 334   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/libopenjp2.pc.cmake.in
 335     ${CMAKE_CURRENT_BINARY_DIR}/libopenjp2.pc @ONLY)
 336   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjp2.pc DESTINATION
 337     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 338 #
 339   if(BUILD_JPWL)
 340   # install in lib and not share (see multi-arch note above)
 341   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjpwl/libopenjpwl.pc.cmake.in
 342     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpwl.pc @ONLY)
 343   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpwl.pc DESTINATION
 344     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 345   endif()
 346 #
 347   if(BUILD_JPIP)
 348   # install in lib and not share (see multi-arch note above)
 349   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjpip/libopenjpip.pc.cmake.in
 350     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpip.pc @ONLY)
 351   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpip.pc DESTINATION
 352     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 353   endif()
 354 #
 355   if(BUILD_JP3D)
 356   # install in lib and not share (see multi-arch note above)
 357   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp3d/libopenjp3d.pc.cmake.in
 358     ${CMAKE_CURRENT_BINARY_DIR}/libopenjp3d.pc @ONLY)
 359   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjp3d.pc DESTINATION
 360     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 361   endif()
 362 endif()
 363
 364 #-----------------------------------------------------------------------------