CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # set(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 cmake_minimum_required(VERSION 2.8.2)
  11
  12 if(COMMAND CMAKE_POLICY)
  13   cmake_policy(SET CMP0003 NEW)
  14 endif()
  15
  16 if(NOT OPENJPEG_NAMESPACE)
  17   set(OPENJPEG_NAMESPACE "OPENJPEG")
  18   set(OPENJPEG_STANDALONE 1)
  19 endif()
  20 # In all cases:
  21 #string(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22 set(OPENJPEG_LIBRARY_NAME openjp2)
  23
  24 project(${OPENJPEG_NAMESPACE} C)
  25
  26 # Do full dependency headers.
  27 include_regular_expression("^.*$")
  28
  29 #-----------------------------------------------------------------------------
  30 # OPENJPEG version number, useful for packaging and doxygen doc:
  31 set(OPENJPEG_VERSION_MAJOR 2)
  32 set(OPENJPEG_VERSION_MINOR 1)
  33 set(OPENJPEG_VERSION_BUILD 0)
  34 set(OPENJPEG_VERSION
  35   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  36 set(PACKAGE_VERSION
  37   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  38
  39 # Because autotools does not support X.Y notation for SOVERSION, we have to use
  40 # two numbering, one for the openjpeg version and one for openjpeg soversion
  41 # version | soversion
  42 #   1.0   |  0
  43 #   1.1   |  1
  44 #   1.2   |  2
  45 #   1.3   |  3
  46 #   1.4   |  4
  47 #   1.5   |  5
  48 #   1.5.1 |  5
  49 #   2.0   |  6
  50 #   2.0.1 |  6
  51 #   2.1   |  7
  52 # above is the recommendation by the OPJ team. If you really need to override this default,
  53 # you can specify your own OPENJPEG_SOVERSION at cmake configuration time:
  54 # cmake -DOPENJPEG_SOVERSION:STRING=42 /path/to/openjpeg
  55 if(NOT OPENJPEG_SOVERSION)
  56   SET(OPENJPEG_SOVERSION 7)
  57 endif(NOT OPENJPEG_SOVERSION)
  58 set(OPENJPEG_LIBRARY_PROPERTIES
  59   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  60   SOVERSION "${OPENJPEG_SOVERSION}"
  61 )
  62
  63 # --------------------------------------------------------------------------
  64 # Path to additional CMake modules
  65 set(CMAKE_MODULE_PATH
  66     ${CMAKE_SOURCE_DIR}/cmake
  67     ${CMAKE_MODULE_PATH})
  68
  69 # --------------------------------------------------------------------------
  70 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  71 # warnings
  72 if(WIN32)
  73   if(NOT BORLAND)
  74     if(NOT CYGWIN)
  75       if(NOT MINGW)
  76         if(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  77           add_definitions(
  78             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  79             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  80             -D_CRT_MANAGED_FP_NO_DEPRECATE
  81             -D_CRT_NONSTDC_NO_DEPRECATE
  82             -D_CRT_SECURE_NO_DEPRECATE
  83             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  84             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  85             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  86             -D_CRT_VCCLRIT_NO_DEPRECATE
  87             -D_SCL_SECURE_NO_DEPRECATE
  88             )
  89         endif()
  90       endif()
  91     endif()
  92   endif()
  93 endif()
  94
  95
  96 # --------------------------------------------------------------------------
  97 # Install directories
  98 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
  99 option(BUILD_DOC "Build the HTML documentation (with doxygen if available)." OFF)
 100
 101 string(TOLOWER ${PROJECT_NAME} projectname)
 102 set(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
 103
 104 if(NOT OPENJPEG_INSTALL_BIN_DIR)
 105   set(OPENJPEG_INSTALL_BIN_DIR "bin")
 106 endif()
 107
 108 if(NOT OPENJPEG_INSTALL_LIB_DIR)
 109   set(OPENJPEG_INSTALL_LIB_DIR "lib")
 110 endif()
 111
 112 if(NOT OPENJPEG_INSTALL_SHARE_DIR)
 113   set(OPENJPEG_INSTALL_SHARE_DIR "share")
 114 endif()
 115
 116 if(NOT OPENJPEG_INSTALL_DATA_DIR)
 117   set(OPENJPEG_INSTALL_DATA_DIR "${OPENJPEG_INSTALL_SHARE_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 118 endif()
 119
 120 if(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
 121   set(OPENJPEG_INSTALL_INCLUDE_DIR "include/${OPENJPEG_INSTALL_SUBDIR}")
 122 endif()
 123
 124 if(BUILD_DOC)
 125 if(NOT OPENJPEG_INSTALL_MAN_DIR)
 126   set(OPENJPEG_INSTALL_MAN_DIR "share/man/")
 127 endif()
 128
 129 if(NOT OPENJPEG_INSTALL_DOC_DIR)
 130   set(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 131 endif()
 132 endif()
 133
 134 if(NOT OPENJPEG_INSTALL_JNI_DIR)
 135   if(WIN32)
 136     set(OPENJPEG_INSTALL_JNI_DIR ${OPENJPEG_INSTALL_BIN_DIR})
 137   else()
 138     set(OPENJPEG_INSTALL_JNI_DIR ${OPENJPEG_INSTALL_LIB_DIR})
 139   endif()
 140 endif()
 141
 142 if(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 143   # We could install *.cmake files in share/ however those files contains
 144   # hardcoded path to libraries on a multi-arch system (fedora/debian) those
 145   # path will be different (lib/i386-linux-gnu vs lib/x86_64-linux-gnu)
 146   set(OPENJPEG_INSTALL_PACKAGE_DIR "${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 147 endif()
 148
 149 if (APPLE)
 150         list(APPEND OPENJPEG_LIBRARY_PROPERTIES INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${OPENJPEG_INSTALL_LIB_DIR}")
 151 endif()
 152
 153 #-----------------------------------------------------------------------------
 154 # Big endian test:
 155 include (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 156 TEST_BIG_ENDIAN(OPJ_BIG_ENDIAN)
 157
 158 #-----------------------------------------------------------------------------
 159 # Setup file for setting custom ctest vars
 160 configure_file(
 161   ${CMAKE_SOURCE_DIR}/cmake/CTestCustom.cmake.in
 162   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 163   @ONLY
 164   )
 165
 166 #-----------------------------------------------------------------------------
 167 # OpenJPEG build configuration options.
 168 option(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 169 set (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 170 set (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 171 mark_as_advanced(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 172
 173 #-----------------------------------------------------------------------------
 174 # configure name mangling to allow multiple libraries to coexist
 175 # peacefully
 176 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 177 set(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 178 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 179                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 180                @ONLY)
 181 endif()
 182
 183 #-----------------------------------------------------------------------------
 184 # Compiler specific flags:
 185 if(CMAKE_COMPILER_IS_GNUCC)
 186   # For all builds, make sure openjpeg is std99 compliant:
 187   # set(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 188   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 189   set(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 190 endif()
 191
 192 #-----------------------------------------------------------------------------
 193 # opj_config.h generation (1/2)
 194
 195 # Check if some include files are provided by the system
 196 include(EnsureFileInclude)
 197 # These files are mandatory
 198 ensure_file_include("string.h"   HAVE_STRING_H YES)
 199 ensure_file_include("memory.h"   HAVE_MEMORY_H YES)
 200 ensure_file_include("stdlib.h"   HAVE_STDLIB_H YES)
 201 ensure_file_include("stdio.h"    HAVE_STDIO_H  YES)
 202 ensure_file_include("math.h"     HAVE_MATH_H   YES)
 203 ensure_file_include("float.h"    HAVE_FLOAT_H  YES)
 204 ensure_file_include("time.h"     HAVE_TIME_H   YES)
 205 ensure_file_include("stdarg.h"   HAVE_STDARG_H YES)
 206 ensure_file_include("ctype.h"    HAVE_CTYPE_H  YES)
 207 ensure_file_include("assert.h"   HAVE_ASSERT_H YES)
 208
 209 # For the following files, we provide an alternative, they are not mandatory
 210 ensure_file_include("stdint.h"   OPJ_HAVE_STDINT_H   NO)
 211 ensure_file_include("inttypes.h" OPJ_HAVE_INTTYPES_H NO)
 212
 213 # why check this one ? for openjpip ?
 214 include (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 215 CHECK_INCLUDE_FILE("strings.h"      HAVE_STRINGS_H)
 216 CHECK_INCLUDE_FILE("sys/stat.h"     HAVE_SYS_STAT_H)
 217 CHECK_INCLUDE_FILE("sys/types.h"    HAVE_SYS_TYPES_H)
 218 CHECK_INCLUDE_FILE("unistd.h"       HAVE_UNISTD_H)
 219
 220 # Enable Large file support
 221 include(TestLargeFiles)
 222 OPJ_TEST_LARGE_FILES(OPJ_HAVE_LARGEFILES)
 223
 224 #-----------------------------------------------------------------------------
 225 # Build Library
 226 if(BUILD_JPIP_SERVER)
 227   find_package(CURL REQUIRED)
 228   find_package(FCGI REQUIRED)
 229   find_package(Threads REQUIRED)
 230   if(NOT CMAKE_USE_PTHREADS_INIT)
 231     message(FATAL_ERROR "Only pthread are supported")
 232   endif()
 233 endif()
 234 add_subdirectory(src/lib)
 235
 236 #-----------------------------------------------------------------------------
 237 # Build Applications
 238 option(BUILD_CODEC "Build the CODEC executables" ON)
 239 option(BUILD_MJ2 "Build the MJ2 executables." OFF)
 240 option(BUILD_JPWL "Build the JPWL library and executables" OFF)
 241 option(BUILD_JPIP "Build the JPIP library and executables." OFF)
 242 if(BUILD_JPIP)
 243   option(BUILD_JPIP_SERVER "Build the JPIP server." OFF)
 244 endif()
 245 option(BUILD_VIEWER "Build the OPJViewer executable (C++)" OFF)
 246 option(BUILD_JAVA "Build the openjpeg jar (Java)" OFF)
 247 option(BUILD_JP3D "Build the JP3D comp" OFF)
 248 mark_as_advanced(BUILD_VIEWER)
 249 mark_as_advanced(BUILD_JAVA)
 250 mark_as_advanced(BUILD_JP3D)
 251
 252 if(BUILD_CODEC OR BUILD_MJ2)
 253   # OFF: It will only build 3rd party libs if they are not found on the system
 254   # ON: 3rd party libs will ALWAYS be build, and used
 255   option(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 256   add_subdirectory(thirdparty)
 257   add_subdirectory(src/bin)
 258 endif ()
 259 add_subdirectory(wrapping)
 260
 261 #-----------------------------------------------------------------------------
 262 # opj_config.h generation (2/2)
 263 configure_file(
 264  ${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/opj_config.h.cmake.in
 265  ${CMAKE_CURRENT_BINARY_DIR}/src/lib/openjp2/opj_config.h
 266  @ONLY
 267  )
 268
 269  configure_file(
 270  ${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/opj_config_private.h.cmake.in
 271  ${CMAKE_CURRENT_BINARY_DIR}/src/lib/openjp2/opj_config_private.h
 272  @ONLY
 273  )
 274
 275 #-----------------------------------------------------------------------------
 276 # build documentation in doc subdir:
 277 if(BUILD_DOC)
 278   add_subdirectory(doc)
 279 endif()
 280
 281 #-----------------------------------------------------------------------------
 282 # Buld Testing
 283 option(BUILD_TESTING "Build the tests." OFF)
 284 if(BUILD_TESTING)
 285   if(BUILD_CODEC)
 286     enable_testing()
 287     include(CTest)
 288
 289     # Search openjpeg data needed for the tests
 290     # They could be found via svn on the OpenJPEG google code project
 291     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 292     find_path(OPJ_DATA_ROOT README-OPJ-Data
 293       PATHS $ENV{OPJ_DATA_ROOT} ${CMAKE_SOURCE_DIR}/../data
 294       NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH
 295       )
 296
 297     # Add repository where to find tests
 298     add_subdirectory(tests)
 299
 300   else()
 301     message(FATAL_ERROR "You need build codec to run the tests")
 302   endif()
 303 endif()
 304
 305 #-----------------------------------------------------------------------------
 306 # install all targets referenced as OPENJPEGTargets
 307 install(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 308 configure_file( ${OPENJPEG_SOURCE_DIR}/cmake/OpenJPEGConfig.cmake.in
 309   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 310   @ONLY
 311 )
 312 install( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 313   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 314 )
 315
 316 #-----------------------------------------------------------------------------
 317 # install CHANGES and LICENSE
 318 if(BUILD_DOC)
 319 if(EXISTS ${OPENJPEG_SOURCE_DIR}/CHANGES)
 320   install(FILES CHANGES DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 321 endif()
 322
 323 install(FILES LICENSE DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 324 endif()
 325
 326 include (cmake/OpenJPEGCPack.cmake)
 327
 328 #-----------------------------------------------------------------------------
 329 # pkgconfig support
 330 # enabled by default on Unix, disabled by default on other platforms
 331 if(UNIX)
 332   option(BUILD_PKGCONFIG_FILES "Build and install pkg-config files" ON)
 333 else()
 334   option(BUILD_PKGCONFIG_FILES "Build and install pkg-config files" OFF)
 335 endif()
 336 if(BUILD_PKGCONFIG_FILES)
 337   # install in lib and not share (see multi-arch note above)
 338   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp2/libopenjp2.pc.cmake.in
 339     ${CMAKE_CURRENT_BINARY_DIR}/libopenjp2.pc @ONLY)
 340   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjp2.pc DESTINATION
 341     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 342 #
 343   if(BUILD_JPWL)
 344   # install in lib and not share (see multi-arch note above)
 345   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjpwl/libopenjpwl.pc.cmake.in
 346     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpwl.pc @ONLY)
 347   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpwl.pc DESTINATION
 348     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 349   endif()
 350 #
 351   if(BUILD_JPIP)
 352   # install in lib and not share (see multi-arch note above)
 353   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjpip/libopenjpip.pc.cmake.in
 354     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpip.pc @ONLY)
 355   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpip.pc DESTINATION
 356     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 357   endif()
 358 #
 359   if(BUILD_JP3D)
 360   # install in lib and not share (see multi-arch note above)
 361   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/lib/openjp3d/libopenjp3d.pc.cmake.in
 362     ${CMAKE_CURRENT_BINARY_DIR}/libopenjp3d.pc @ONLY)
 363   install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjp3d.pc DESTINATION
 364     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 365   endif()
 366 endif()
 367
 368 #-----------------------------------------------------------------------------