tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 3.5)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     edf_c2_1377017.jp2
  38     edf_c2_1002767.jp2
  39     edf_c2_10025.jp2
  40     edf_c2_1000234.jp2
  41     edf_c2_225881.jp2
  42     edf_c2_1000671.jp2
  43     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  44     edf_c2_1015644.jp2
  45     edf_c2_101463.jp2
  46     edf_c2_1674177.jp2
  47     edf_c2_1673169.jp2
  48     issue418.jp2
  49     issue429.jp2
  50     issue427-null-image-size.jp2
  51     issue427-illegal-tile-offset.jp2
  52     issue495.jp2
  53     issue820.jp2
  54    )
  55
  56 # Define a list of file which should be gracefully rejected:
  57 set(BLACKLIST_JPEG2000
  58     ${BLACKLIST_JPEG2000_TMP}
  59     broken1.jp2
  60     broken2.jp2
  61     broken3.jp2
  62     broken4.jp2
  63     edf_c2_20.jp2 #may look ok as per kdu_jp2info, but inspection it reveals that the transformation value is out of range
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84     issue823.jp2 #kdu_jp2info ok
  85     issue826.jp2 #inspection reveales that the transformation value is out of range
  86     oss-fuzz2785.jp2 #inspection reveales that the transformation value is out of range
  87     issue1438.j2k
  88    )
  89
  90 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  91      "${INPUT_NR}/*.j2k"
  92      "${INPUT_NR}/*.j2c"
  93      "${INPUT_NR}/*.jp2"
  94      "${INPUT_NR}/*.jpc"
  95      "${INPUT_NR}/*.jph"
  96      "${INPUT_NR}/*.jhc"
  97      #"${INPUT_NR}/*.jpx"
  98      )
  99
 100 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
 101   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 102   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 103   # cannot use longest extension function, since some name contains multiples
 104   # dots. Instead write out own shortest extension function:
 105   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 106   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 107   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 108
 109   # Dump the input image
 110   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 111            COMMAND opj_dump
 112                -i ${INPUT_FILENAME}
 113                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 114                -v
 115                )
 116
 117   if(bad_jpeg2000)
 118     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 119                          PROPERTIES WILL_FAIL TRUE)
 120
 121   else()
 122
 123     # Compare the dump output with the baseline
 124     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 125                 COMMAND compare_dump_files
 126             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 127             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 128             )
 129
 130     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 131                          PROPERTIES DEPENDS
 132                          NR-${INPUT_FILENAME_NAME}-dump)
 133   endif()
 134
 135 endforeach()
 136
 137
 138 #########################################################################
 139 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 140 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 141 # to know which files processed and with which options.
 142
 143 # Configure the test suite file:
 144 configure_file("test_suite.ctest.in"
 145                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 146                @ONLY)
 147
 148 # Read the file into a list
 149 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 150
 151 # Try to find and configure and read another test suite file
 152 file(GLOB TEST_SUITE_FILES *.ctest.in)
 153 if (TEST_SUITE_FILES)
 154   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 155
 156     # Avoid to process the official test suite
 157     set(FILE_ALREADY_READ 0)
 158     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 159     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 160
 161     if(NOT FILE_ALREADY_READ)
 162       # Configure the additional test suite file:
 163       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 164       configure_file("${TEST_SUITE_FILE}"
 165                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 166                      @ONLY)
 167       # Read the additional file into a list
 168       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 169       # Append the list of command
 170       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 171
 172     endif()
 173
 174   endforeach()
 175
 176 else()
 177
 178   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 179
 180 endif()
 181
 182
 183 set(nonregression_filenames_used)
 184 # Parse the command line found in the file(s)
 185 set(IT_TEST_ENC 0)
 186 set(IT_TEST_DEC 0)
 187 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 188
 189   set(IGNORE_LINE_FOUND 0)
 190
 191   # Replace space by ; to generate a list
 192   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 193
 194   # Check if the first argument begin by the comment sign
 195   list(GET CMD_ARG_LIST 0 EXE_NAME)
 196
 197   if(EXE_NAME)
 198     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 199   endif()
 200
 201   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 202
 203     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 204
 205   else()
 206
 207     # Check if the first argument begin by the failed sign
 208     set(FAILED_TEST_FOUND 0)
 209     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 210
 211     if (FAILED_TEST_FOUND)
 212       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 213       set(FAILED_TEST_FOUND_1 0)
 214       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 215
 216       if (FAILED_TEST_FOUND_1)
 217
 218         list(REMOVE_AT CMD_ARG_LIST 0)
 219
 220       else ()
 221
 222         set(FAILED_TEST_FOUND_2 0)
 223         list(GET CMD_ARG_LIST 1 EXE_NAME)
 224         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 225
 226         if (FAILED_TEST_FOUND_2)
 227
 228           list(REMOVE_AT CMD_ARG_LIST 0)
 229           list(REMOVE_AT CMD_ARG_LIST 0)
 230
 231         else ()
 232
 233           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 234
 235         endif ()
 236       endif ()
 237
 238     else ()
 239       # Check if the first argument is equal to opj_compress
 240       string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 241
 242       if(EXE_NAME_FOUND)
 243
 244         string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" ENC_TEST_FOUND ${EXE_NAME})
 245         string(REGEX MATCH "^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" NO_RAW ${EXE_NAME})
 246         string(REGEX MATCH "opj_compress_no_raw_lossless" LOSSLESS ${EXE_NAME})
 247
 248       else()
 249
 250         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 251
 252       endif()
 253
 254       list(REMOVE_AT CMD_ARG_LIST 0)
 255
 256       if(ENC_TEST_FOUND)
 257
 258         # Parse lines like opj_compress lossy-check { -n 3 -m 0:0:0 -p 0:0:0 } ...
 259         set(LOSSY_CHECK_ARG_LIST "")
 260         list(GET CMD_ARG_LIST 0 NEXT_ARG)
 261         string(REGEX MATCH "^lossy-check$" LOSSY_CHECK ${NEXT_ARG})
 262         if(LOSSY_CHECK)
 263             list(REMOVE_AT CMD_ARG_LIST 0)
 264             list(GET CMD_ARG_LIST 0 NEXT_ARG)
 265             string(REGEX MATCH "^{$" FOUND_OPEN_CURL ${NEXT_ARG})
 266             if(NOT FOUND_OPEN_CURL)
 267                 message( FATAL_ERROR "'{' expected after lossy-check")
 268             endif()
 269             list(REMOVE_AT CMD_ARG_LIST 0)
 270             while(TRUE)
 271                 list(GET CMD_ARG_LIST 0 NEXT_ARG)
 272                 list(REMOVE_AT CMD_ARG_LIST 0)
 273                 string(REGEX MATCH "^}$" FOUND_CLOSE_CURL ${NEXT_ARG})
 274                 if(FOUND_CLOSE_CURL)
 275                     break()
 276                 endif()
 277                 list (APPEND LOSSY_CHECK_ARG_LIST ${NEXT_ARG})
 278             endwhile()
 279         endif()
 280       endif()
 281
 282     endif ()
 283
 284     # Parse the argument list to find the input filename and output filename
 285     set(CMD_ARG_LIST_2 "")
 286     set(ARG_POS 0)
 287     set(INPUT_ARG_POS 0)
 288     set(OUTPUT_ARG_POS 0)
 289
 290     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 291
 292       math(EXPR ARG_POS "${ARG_POS}+1" )
 293
 294       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 295       if(INPUT_ARG_FOUND)
 296         set(INPUT_ARG_POS ${ARG_POS})
 297         set(INPUT_ARG_FOUND 0)
 298       endif()
 299
 300       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 301       if(OUTPUT_ARG_FOUND)
 302         set(OUTPUT_ARG_POS ${ARG_POS})
 303         set(OUTPUT_ARG_FOUND 0)
 304       endif()
 305
 306       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 307
 308     endforeach()
 309
 310     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 311     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 312     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 313     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 314     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 315
 316     #-----
 317     # Now we can add the test suite corresponding to a line command in the file
 318     #-----
 319     # ENCODER TEST SUITE
 320     if(ENC_TEST_FOUND)
 321         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 322
 323         # Encode an image into the jpeg2000 format
 324         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 325           COMMAND opj_compress
 326           ${CMD_ARG_LIST_2}
 327         )
 328
 329         if(FAILED_TEST_FOUND)
 330             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 331         else()
 332
 333           # Dump the encoding file
 334           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 335             COMMAND opj_dump
 336             -i ${OUTPUT_FILENAME}
 337             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 338           )
 339           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 340                                PROPERTIES DEPENDS
 341                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 342
 343           # Compare the dump file with the baseline
 344           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 345             COMMAND compare_dump_files
 346             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 347             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 348           )
 349
 350           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 351                                PROPERTIES DEPENDS
 352                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 353
 354           if(LOSSY_CHECK)
 355             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 356             COMMAND opj_decompress
 357             -i ${OUTPUT_FILENAME}
 358             -o ${OUTPUT_FILENAME}.tif
 359             )
 360
 361             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 362                                 PROPERTIES DEPENDS
 363                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 364
 365             # Compare the decoding file with original one, using tolerance
 366             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 367             COMMAND compare_images
 368             -b ${INPUT_FILENAME}
 369             -t ${OUTPUT_FILENAME}.tif
 370             -s bXtY
 371             ${LOSSY_CHECK_ARG_LIST}
 372             )
 373
 374             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 375                                 PROPERTIES DEPENDS
 376                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 377
 378           # Decode the encoding file with kakadu expand command
 379           elseif (KDU_EXPAND_EXECUTABLE)
 380             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 381               COMMAND ${KDU_EXPAND_EXECUTABLE}
 382               -i ${OUTPUT_FILENAME}
 383               -o ${OUTPUT_FILENAME}.raw
 384               )
 385
 386             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 387                                  PROPERTIES DEPENDS
 388                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 389
 390             if(NOT NO_RAW)
 391                 # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 392                 add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 393                 COMMAND compare_raw_files
 394                 -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 395                 -t ${OUTPUT_FILENAME}.raw
 396                 )
 397
 398                 set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 399                                     PROPERTIES DEPENDS
 400                                     NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 401             endif()
 402           endif()
 403
 404           # Test the encoded file is a valid JP2 file
 405           if (JPYLYZER_EXECUTABLE)
 406             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 407               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 408                 COMMAND ${JPYLYZER_EXECUTABLE}
 409                 ${OUTPUT_FILENAME}
 410                 )
 411               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 412                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 413                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 414                 )
 415             endif()
 416           endif(JPYLYZER_EXECUTABLE)
 417
 418           # If lossless compression (simple test is 4 arguments), decompress & compare
 419           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 420           if ((ARG_COUNT EQUAL 4) OR LOSSLESS)
 421             # can we compare with the input image ?
 422             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 423               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 424                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 425                 )
 426               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 427                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 428                 )
 429               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 430                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 431                 )
 432               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 433                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 434                 )
 435             endif()
 436           endif()
 437       endif()
 438
 439     # DECODER TEST SUITE
 440     else()
 441       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 442       if(${nr_pos} GREATER 0)
 443         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 444       endif()
 445       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 446
 447       # Decode the input image
 448       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 449         COMMAND opj_decompress
 450         ${CMD_ARG_LIST_2}
 451       )
 452
 453       if(FAILED_TEST_FOUND)
 454
 455         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 456
 457       else()
 458         # if not failed, check against registered md5:
 459         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 460           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 461           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 462           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 463
 464         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 465           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 466         )
 467
 468 # FIXME: add a compare2base function base on raw which
 469 # can output png diff files if necessary
 470 #  add_test(NR-${filename}-compare2base
 471 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 472 #     -b ${BASELINE_NR}/opj_${filenameRef}
 473 #     -t ${TEMP}/${filename}.pgx
 474 #     -n ${nbComponents}
 475 #     -d
 476 #     -s b_t_
 477 #     )
 478 #
 479 #  set_tests_properties(NR-${filename}-compare2base
 480 #                       PROPERTIES DEPENDS
 481 #                       NR-${filename}-decode)
 482
 483       endif()
 484
 485     endif()
 486
 487   endif()
 488
 489 endforeach()
 490
 491 set(existing_filenames)
 492 foreach(f ${OPJ_DATA_NR_LIST})
 493   get_filename_component(ff ${f} NAME)
 494   list(APPEND existing_filenames ${ff})
 495 endforeach()
 496 if(existing_filenames)
 497 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 498 endif()
 499
 500 # keep track of new addition:
 501 # if we reach here, then a J2K files was added but no test is present in
 502 # test_suite.ctest.in:
 503 foreach(found_but_no_test ${existing_filenames})
 504   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 505   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 506 endforeach()