configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30
  31 # Check version number coherency between RtAudio.h and configure.ac
  32 AC_MSG_CHECKING([that version numbers are coherent])
  33 AC_RUN_IFELSE(
  34    [AC_LANG_PROGRAM([#include <string.h>
  35                      `grep "define RTAUDIO_VERSION" $srcdir/RtAudio.h`],
  36                     [return strcmp(RTAUDIO_VERSION, PACKAGE_VERSION);])],
  37    [AC_MSG_RESULT([yes])],
  38    [AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])])
  39
  40 # Enable some nice automake features if they are available
  41 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43
  44 # Fill GXX with something before test.
  45 AC_SUBST( GXX, ["no"] )
  46
  47 dnl Check for pkg-config program, used for configuring some libraries.
  48 m4_define_default([PKG_PROG_PKG_CONFIG],
  49 [AC_MSG_CHECKING([pkg-config])
  50 AC_MSG_RESULT([no])])
  51
  52 PKG_PROG_PKG_CONFIG
  53
  54 dnl If the pkg-config autoconf support isn't installed, define its
  55 dnl autoconf macro to disable any packages depending on it.
  56 m4_define_default([PKG_CHECK_MODULES],
  57 [AC_MSG_CHECKING([$1])
  58 AC_MSG_RESULT([no])
  59 $4])
  60
  61 # Check for debug
  62 AC_MSG_CHECKING(whether to compile debug version)
  63 AC_ARG_ENABLE(debug,
  64   [AS_HELP_STRING([--enable-debug],[enable various debug output])],
  65   [: ${CXXFLAGS="-g -O0"};] [AC_DEFINE([__RTAUDIO_DEBUG__])],
  66   [: ${CXXFLAGS="-O3"}])
  67
  68 # Checks for programs.
  69 AC_PROG_CXX(g++ CC c++ cxx)
  70 AM_PROG_AR
  71 AC_PATH_PROG(AR, ar, no)
  72 if [[ $AR = "no" ]] ; then
  73     AC_MSG_ERROR("Could not find ar - needed to create a library");
  74 fi
  75
  76 # Initialize libtool
  77 LT_INIT([win32-dll])
  78 AC_CONFIG_MACRO_DIR([m4])
  79
  80 # Checks for header files.
  81 AC_HEADER_STDC
  82 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  83
  84 # Check compiler and use -Wall if gnu
  85 if test x"$GXX" = "xyes"; then
  86   CXXFLAGS="${CXXFLAGS} -Wall -Wextra"
  87   # Add -Werror in debug mode
  88   if test x"${enable_debug+set}" = xset; then
  89     CXXFLAGS="${CXXFLAGS} -Werror"
  90   fi
  91 fi
  92
  93 # Checks for functions
  94 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
  95
  96 # Checks for doxygen
  97 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
  98 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x] )
  99
 100 # Copy doc files to build dir if necessary
 101 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 102 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 103 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 104 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 105 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 106 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 107 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 108 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 109 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 110 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 111 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 112 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 113 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 114 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 115 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 116 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 117 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 118
 119 # Checks for package options and external software
 120 AC_CANONICAL_HOST
 121
 122 AC_SUBST( api, [""] )
 123 AC_SUBST( req, [""] )
 124 AC_MSG_CHECKING(for audio API)
 125
 126 AC_ARG_WITH(jack, [  --with-jack = choose JACK server support (mac and linux only)])
 127 AS_IF([test "x$with_jack" == "xyes"], [
 128   api="$api -D__UNIX_JACK__"
 129   AC_MSG_RESULT(using JACK)
 130   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR(JACK support requires the jack library!))])
 131
 132 case $host in
 133   *-*-netbsd*)
 134   AS_IF([test "$api" == ""], [
 135     AC_MSG_RESULT(using OSS)
 136     api="$api -D__LINUX_OSS__"
 137     LIBS="$LIBS -lossaudio"
 138     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))])
 139   ;;
 140
 141   *-*-freebsd*)
 142   AS_IF([test "$api" == ""], [
 143     AC_MSG_RESULT(using OSS)
 144     api="$api -D__LINUX_OSS__"
 145     LIBS="$LIBS -lossaudio"
 146     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))])
 147   ;;
 148
 149   *-*-linux*)
 150   # Look for ALSA flag
 151   AC_ARG_WITH(alsa, [  --with-alsa = choose native ALSA API support (linux only)])
 152   AS_IF([test "x$with_alsa" == "xyes"], [
 153     api="$api -D__LINUX_ALSA__"
 154     req="$req alsa"
 155     AC_MSG_RESULT(using ALSA)
 156     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))])
 157
 158   # Look for PULSE flag
 159   AC_ARG_WITH(pulse, [  --with-pulse = choose PulseAudio API support (linux only)])
 160   AS_IF([test "x$with_pulse" == "xyes"], [
 161     api="$api -D__LINUX_PULSE__"
 162     req="$req libpulse-simple"
 163     AC_MSG_RESULT(using PulseAudio)
 164     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR(PulseAudio support requires the pulse-simple library!))])
 165
 166   # Look for OSS flag
 167   AC_ARG_WITH(oss, [  --with-oss = choose OSS API support (unixes)])
 168   AS_IF([test "x$with_oss" == "xyes"], [
 169     api="$api -D__LINUX_OSS__"
 170     AC_MSG_RESULT(using OSS)])
 171
 172   # If no audio api flags specified, use ALSA
 173   if [test "$api" == "";] then
 174     AC_MSG_RESULT(using ALSA)
 175     AC_SUBST( api, [-D__LINUX_ALSA__] )
 176     req="$req alsa"
 177     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 178   fi
 179
 180   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 181   ;;
 182
 183   *-apple*)
 184   # Look for Core flag
 185   AC_ARG_WITH(core, [  --with-core = choose CoreAudio API support (mac only)])
 186   AS_IF([test "x$with_core" == "xyes"], [
 187     api="$api -D__MACOSX_CORE__"
 188     AC_MSG_RESULT(using CoreAudio)
 189     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR(CoreAudio header files not found!)] )
 190     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation" ])
 191
 192   # If no audio api flags specified, use CoreAudio
 193   if [test "$api" == ""; ] then
 194     AC_SUBST( api, [-D__MACOSX_CORE__] )
 195     AC_MSG_RESULT(using CoreAudio)
 196     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 197       [],
 198       [AC_MSG_ERROR(CoreAudio header files not found!)] )
 199     AC_SUBST( LIBS, ["-framework CoreAudio -framework CoreFoundation"] )
 200   fi
 201
 202   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 203   ;;
 204
 205   *-mingw32*)
 206   AC_ARG_WITH(asio, [  --with-asio = choose ASIO API support (windoze only)])
 207   AS_IF([test "x$with_asio" == "xyes"], [
 208     api="$api -D__WINDOWS_ASIO__"
 209     AC_MSG_RESULT(using ASIO)
 210     AC_SUBST( objects, ["asio.o asiodrivers.o asiolist.o iasiothiscallresolver.o"] ) ])
 211
 212   # Look for DirectSound flag
 213   AC_ARG_WITH(ds, [  --with-ds = choose DirectSound API support (windoze only)])
 214   AS_IF([test "x$with_ds" == "xyes"], [
 215     api="$api -D__WINDOWS_DS__"
 216     AC_MSG_RESULT(using DirectSound)
 217     LIBS="-ldsound -lwinmm $LIBS" ])
 218
 219   # Look for WASAPI flag
 220   AC_ARG_WITH(wasapi, [  --with-wasapi = choose Windows Audio Session API support (windoze only)])
 221   AS_IF([test "x$with_wasapi" == "xyes"], [
 222     api="$api -D__WINDOWS_WASAPI__"
 223     AC_MSG_RESULT(using WASAPI)
 224     LIBS="-lwinmm -luuid -lksuser $LIBS" ])
 225
 226   # If no audio api flags specified, use DS
 227   if [test "$api" == "";] then
 228     AC_SUBST( api, [-D__WINDOWS_DS__] )
 229     AC_MSG_RESULT(using DirectSound)
 230     LIBS="-ldsound -lwinmm $LIBS"
 231   fi
 232
 233   LIBS="-lole32 $LIBS"
 234   ;;
 235
 236   *)
 237   # Default case for unknown realtime systems.
 238   AC_MSG_ERROR(Unknown system type for realtime support!)
 239   ;;
 240 esac
 241
 242 CPPFLAGS="$CPPFLAGS $api"
 243
 244 AC_OUTPUT