configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32
  33 api=""
  34 req=""
  35
  36 # Check version number coherency between RtAudio.h and configure.ac
  37 AC_MSG_CHECKING([that version numbers are coherent])
  38 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  39 AS_IF(
  40    [test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],
  41    [AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])]
  42 )
  43 # Enable some nice automake features if they are available
  44 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  45 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  46
  47 # Fill GXX with something before test.
  48 GXX = "no"
  49
  50 dnl Check for pkg-config program, used for configuring some libraries.
  51 m4_define_default([PKG_PROG_PKG_CONFIG],
  52 [AC_MSG_CHECKING([pkg-config])
  53 AC_MSG_RESULT([no])])
  54
  55 PKG_PROG_PKG_CONFIG
  56
  57 dnl If the pkg-config autoconf support isn't installed, define its
  58 dnl autoconf macro to disable any packages depending on it.
  59 m4_define_default([PKG_CHECK_MODULES],
  60 [AC_MSG_CHECKING([$1])
  61 AC_MSG_RESULT([no])
  62 $4])
  63
  64 # Check for debug
  65 AC_MSG_CHECKING(whether to compile debug version)
  66 AC_ARG_ENABLE(debug,
  67   [AS_HELP_STRING([--enable-debug],[enable various debug output])],
  68   [: ${CXXFLAGS="-g -O0"};] [AC_DEFINE([__RTAUDIO_DEBUG__])],
  69   [: ${CXXFLAGS="-O3"}])
  70
  71 # Checks for programs.
  72 AC_PROG_CXX(g++ CC c++ cxx)
  73 AM_PROG_AR
  74 AC_PATH_PROG(AR, ar, no)
  75 AS_IF([test "x${AR} = "xno" ], [
  76     AC_MSG_ERROR("Could not find ar - needed to create a library");
  77 ])
  78
  79 # Initialize libtool
  80 LT_INIT([win32-dll])
  81 AC_CONFIG_MACRO_DIR([m4])
  82
  83 # Checks for header files.
  84 AC_HEADER_STDC
  85 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  86
  87 # Check compiler and use -Wall if gnu
  88 AS_IF([test "x${GXX} = "xyes" ], [
  89   CXXFLAGS="${CXXFLAGS} -Wall -Wextra"
  90   # Add -Werror in debug mode
  91   if test x"${enable_debug+set}" = xset; then
  92     CXXFLAGS="${CXXFLAGS} -Werror"
  93   fi
  94 ])
  95
  96 # Checks for functions
  97 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
  98
  99 # Checks for doxygen
 100 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 101 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x] )
 102
 103 # Copy doc files to build dir if necessary
 104 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 105 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 106 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 107 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 108 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 109 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 110 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 111 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 112 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 113 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 114 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 115 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 116 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 117 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 118 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 119 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 120 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 121
 122 # Checks for package options and external software
 123 AC_CANONICAL_HOST
 124
 125 AC_MSG_CHECKING(for audio API)
 126
 127 AC_ARG_WITH(jack, [  --with-jack = choose JACK server support (mac and linux only)])
 128 AS_IF([test "x$with_jack" = "xyes"], [
 129   AC_MSG_RESULT(using JACK)
 130   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR(JACK support requires the jack library!))
 131   api="$api -D__UNIX_JACK__"
 132 ])
 133
 134 case $host in
 135   *-*-netbsd*)
 136   AS_IF([test "x$api" = "x"], [
 137     AC_MSG_RESULT(using OSS)
 138     api="$api -D__LINUX_OSS__"
 139     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 140     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 141   ])
 142   ;;
 143
 144   *-*-freebsd*)
 145   AS_IF([test "x$api" = "x"], [
 146     AC_MSG_RESULT(using OSS)
 147     api="$api -D__LINUX_OSS__"
 148     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 149     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 150   ])
 151   ;;
 152
 153   *-*-linux*)
 154   # Look for ALSA flag
 155   AC_ARG_WITH(alsa, [  --with-alsa = choose native ALSA API support (linux only)])
 156   AS_IF([test "x$with_alsa" = "xyes"], [
 157     AC_MSG_RESULT(using ALSA)
 158     api="$api -D__LINUX_ALSA__"
 159     req="$req alsa"
 160     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 161   ])
 162
 163   # Look for PULSE flag
 164   AC_ARG_WITH(pulse, [  --with-pulse = choose PulseAudio API support (linux only)])
 165   AS_IF([test "x$with_pulse" = "xyes"], [
 166     AC_MSG_RESULT(using PulseAudio)
 167     api="$api -D__LINUX_PULSE__"
 168     req="$req libpulse-simple"
 169     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR(PulseAudio support requires the pulse-simple library!))
 170   ])
 171
 172   # Look for OSS flag
 173   AC_ARG_WITH(oss, [  --with-oss = choose OSS API support (unixes)])
 174   AS_IF([test "x$with_oss" = "xyes"], [
 175     AC_MSG_RESULT(using OSS)
 176     api="$api -D__LINUX_OSS__"
 177   ])
 178
 179   # If no audio api flags specified, use ALSA
 180   AS_IF([test "x$api" = "x" ], [
 181     AC_MSG_RESULT(using ALSA)
 182     api="${api} -D__LINUX_ALSA__"
 183     req="${req} alsa"
 184     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 185   ])
 186   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 187   ;;
 188
 189   *-apple*)
 190   # Look for Core flag
 191   AC_ARG_WITH(core, [  --with-core = choose CoreAudio API support (mac only)])
 192   AS_IF([test "x$with_core" = "xyes"], [
 193     AC_MSG_RESULT(using CoreAudio)
 194     api="$api -D__MACOSX_CORE__"
 195     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR(CoreAudio header files not found!)] )
 196     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
 197   ])
 198
 199   # If no audio api flags specified, use CoreAudio
 200   AS_IF([test "x$api" = "x" ], [
 201     AC_MSG_RESULT(using CoreAudio)
 202     api="${api} -D__MACOSX_CORE__"
 203     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 204       [],
 205       [AC_MSG_ERROR(CoreAudio header files not found!)] )
 206     LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
 207   ])
 208
 209   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 210   ;;
 211
 212   *-mingw32*)
 213   AC_ARG_WITH(asio, [  --with-asio = choose ASIO API support (windoze only)])
 214   AS_IF([test "x$with_asio" = "xyes" ], [
 215     AC_MSG_RESULT(using ASIO)
 216     api="$api -D__WINDOWS_ASIO__"
 217     AC_SUBST( objects, ["asio.o asiodrivers.o asiolist.o iasiothiscallresolver.o"] )
 218   ])
 219
 220   # Look for DirectSound flag
 221   AC_ARG_WITH(ds, [  --with-ds = choose DirectSound API support (windoze only)])
 222   AS_IF([test "x$with_ds" = "xyes" ], [
 223     AC_MSG_RESULT(using DirectSound)
 224     api="$api -D__WINDOWS_DS__"
 225     LIBS="-ldsound -lwinmm $LIBS"
 226   ])
 227
 228   # Look for WASAPI flag
 229   AC_ARG_WITH(wasapi, [  --with-wasapi = choose Windows Audio Session API support (windoze only)])
 230   AS_IF([test "x$with_wasapi" = "xyes"], [
 231     AC_MSG_RESULT(using WASAPI)
 232     api="$api -D__WINDOWS_WASAPI__"
 233     LIBS="-lwinmm -luuid -lksuser $LIBS"
 234   ])
 235
 236   # If no audio api flags specified, use DS
 237   AS_IF([test "x$api" = "x" ], [
 238     AC_MSG_RESULT(using DirectSound)
 239     api="$api -D__WINDOWS_DS__"
 240     LIBS="-ldsound -lwinmm $LIBS"
 241   ])
 242
 243   LIBS="-lole32 $LIBS"
 244   ;;
 245
 246   *)
 247   # Default case for unknown realtime systems.
 248   AC_MSG_ERROR(Unknown system type for realtime support!)
 249   ;;
 250 esac
 251
 252 CPPFLAGS="$CPPFLAGS $api"
 253
 254 AC_OUTPUT